What does changing a, b, and c do to the graph of y = a x^2 + b x + c?

Which parabola is it that is pointing up instead of down?

q1 = x^2 + 2 x + 1;
q2 = 2 x^2 - 4 x + 3;
q3 = N[Pi] x^2 - 3/2 x + 6.4;
q4 = Expand[-(Sqrt[12.] x - 4)(x + 3)];
q5 = 10 x ^2 - 1;

Plot[{q1, q2, q3, q4, q5}, {x, -4, 4}];

Explain the algebra and the geometry of the parabolas shown here.

TableForm[ Partition[
	Table[x^2 - x + c, {c, -10, 10}], 
3] ]
Plot[Evaluate[%], {x, -4, 4}];

What makes a parabola point up or down?

TableForm[ Partition[
	Table[a x^2 -4 x + 1, {a, -10, 10}], 
3] ]
Plot[Evaluate[%], {x, -4, 4}];

Why do all these parabolas go through the same point?

TableForm[ Partition[
	Table[x^2 +  b x - 5, {b, -10, 10}], 
	3] ]
Plot[Evaluate[%], {x, -6, 6}];

The path of a projectile depends on the gravity, initial velocity, and angle.

Projectile[2, 3, 40];

What angle gives the longest horizontal distance?

Projectiles[1, 1, Range[10, 80, 5]];

This varies the initial velocity.

Projectiles[1, Range[10, 80, 5], 38];

Implementation

Projectile[g_, v_, a_] := Module[
	{t, A}, 
	A = N[a Degree];
	ParametricPlot[
		{
			{Cos[A] t, Sin[A] t}, 
			{v t Cos[A], v t Sin[A] - g t^2 / 2}
		}, 
	{t, 0, 2 v / g Sin[A]}, 
	AspectRatio -> Automatic
	]
]

Projectiles[g_, v_, a_List] := Module[
	{t, A, T}, 
	A = N[a Degree];
	T = Map[
			ParametricPlot[
				{v t Cos[#], v t Sin[#] - g t^2 / 2}, 
				{t, 0, 2 v / g Sin[#]}, 
				DisplayFunction -> Identity
			]&, 
		A
	];
	Show[T, AspectRatio -> Automatic, 
	DisplayFunction -> $DisplayFunction]
]

Projectiles[g_, v_List, a_] := Module[
	{t, A, T}, 
	A = N[a Degree];
	T = Map[
			ParametricPlot[
				{# t Cos[A], # t Sin[A] - g t^2 / 2}, 
				{t, 0, 2 # / g Sin[A]}, 
					DisplayFunction -> Identity
			]&, 
		v
	];
	Show[T, AspectRatio -> Automatic, 
		DisplayFunction -> $DisplayFunction]
]

Projectiles[g_List, v_, a_] := Module[
	{t, A, T}, 
	A = N[a Degree];
	T = Map[
			ParametricPlot[
				{v t Cos[A], v t Sin[A] - # t^2 / 2}, 
				{t, 0, 2 v / # Sin[A]}, 
				DisplayFunction -> Identity
			]&, 
		g
	];
	Show[T, AspectRatio -> Automatic, 
		DisplayFunction -> $DisplayFunction]
]