Broadband Amplifier Design: An Example of Project Documentation

Introduction

<<EE`

Project

A broadband amplifier is required for our CATV chip set. This amplifier will be realized as part of an IC process with resistors and transistors. It was mentioned in the latest project meeting that the following amplifier configuration will make a broadband amplifier with matched input and output impedances. It was also stated that information on the resistor values could not be found, but the amplifier is trivial to analyze.

Mathematica enables you to easily mix graphics with your descriptive text. This graphic was created elsewhere in Mathematica, but it could easily have been pasted in from a circuit-drawing application, or imported from an AutoCAD DXF file. It is said that a picture is worth a thousand words the impact of your presentations can be substantially enhanced by this capability.

Analysis

After some experimentation it was found that this circuit is best analyzed by deriving its input and output impedances and matching these to the system impedance. All biasing analysis will be omitted. The single node formulation of this network equation is used. A subtlety in the following analysis is that since gm is infinity, the voltage at the top of Rs will be driven to be VIn, so V will be zero.

We can represent our circuit for the purposes of analysis.

Zin is the impedance looking into the amplifier; analysis is performed by current at the node drawn as a filled circle.

We have the following equations at the main node.

eqnZinI = 
        {0 == i1 + i2 - i12, i1 == ((vIn - vOut)/Rfb), 
          i2 == -(vOut/zo), vIn == i12 Rs};

We can solve for the input, collecting the current and output voltage terms.

solnZinI=Solve[eqnZinI,vIn,{i2,i12,vOut}]

This, in turn, can be simplified.

ZInI = Simplify[First[(VIn/i1) /. solnZinI]]

Zout is found in a similar fashion. Note that the same base nodal equation is used, but now the output port is analyzed with the input terminated in zo.

eqnZoutI = 
        {0 == i1 + i2 - i12, i1 == -(vIn/zo), vOut == vIn - i1 Rfb, 
          vIn == i12 Rs};

solnZoutI=Solve[eqnZoutI,vOut,{i1,i12,vIn}]

zOutI = Simplify[First[(vOut/i2) /. solnZoutI]]

Now we can solve for the resistor configuration that makes the amplifier matched.

rConstraint=Solve[{zInI==zo,zOutI==zo},Rs][[1,1]]

The missing factor in our design is the gain of our amplifier. We can use Solve again, considering the network driven and terminated in a 50-ohm resistor.

eqnGain = 
        {0 == i1 + i2 - i12, i1 == ((vIn - vOut)/Rfb), 
          i2 == -(vOut/zo), vIn == i12 Rs, v1 == vIn + i1 zo};

solnGain=Solve[eqnGain,vOut,{i1,i2,i12,v1}]

gain = Simplify[First[(vOut/vIn) /. solnGain]]

Our system impedance, zo, is typically 50 or 75 ohms. Once we substitute the constraint on Rs, we have our gain in terms of Rfb.

RfbSoln=gain/.rConstraint

Result

This nonlinear equation becomes our amplifier design equation because we are typically given a gain specification and told to design the amplifier. Most system designers keep specifications to 5-decibel increments, so a table of designs will probably be all we will ever need. We can use the Mathematica function FindRoot to solve the gain equation and then backsolve for Rs. Since most amplifiers are between 5 and 30 decibels of gain we will confine our table to that range. We will also use a 50-ohm system.

We begin by setting up a range of decibel values.

gainsDB=Range[5,30,5];

We then establish the gain equation. Note that the equation assumes an inverting amplifier.

gainEqn=Abs[RfbSoln/.zo->50.0];

We can now solve the equation.

rfbs = 
      (Rfb /. FindRoot[gainEqn - (10.0^(#(1/20.0))), {Rfb, {50, 500}}] &) 
        /@ gainsDB

The next step is to find our Rs values.

rsVals=Rs/.rConstraint/.Rfb->rfbs/.{zo->50};

We can place the derived values in tabular form.

NumberForm[TableForm[Transpose[{gainsDB,rfbs,N[rsVals]}],TableHeadings->{None,{"GainDB","Rfb","Rs"}},TableSpacing->{0.5,3}],4]

Potential Problems

Mathematica makes it easy for us to test how finite transconductances of real transistors deteriorate the gain and impedance match of this amplifier. We can copy all of the preceding analysis and add in the gm factor.

eqnZin = 
        {0 == i1 + i2 - i12, i1 == ((vIn - vOut)/Rfb), 
          i2 == -(vOut/zo), i12 == gm v, v == vIn - i12 Rs};

solnZin=Solve[eqnZin,vIn,{i2,i12,vOut,v}];

zIn = Simplify[First[(vIn/i1) /. solnZin]]

Finally we substitute our constraint for Rs and set zo to 50 to get zIn in terms of gm and Rfb.

zInFcn[gm_,Rfb_]=Simplify[zIn/.rConstraint/.zo->50]

eqnGain = 
        {0 == i1 + i2 - i12, i1 == ((vIn - vOut)/Rfb), 
          i2 == -(vOut/zo), i12 == gm v, v == vIn - i12 Rs, 
          v1 == vIn + i1 zo};

solnGain = Solve[eqnGain, vOut, {i1, i2, i12, v1, v}];

gain = Simplify[First[(vOut/vIn) /. solnGain]]

Finally we substitute our constraint for Rs and set zo to 50 ohms to get gain in terms of gm and Rfb.

gainFcn[gm_,Rfb_]=Simplify[gain/.rConstraint/.zo->50]

Since we expect our 15-decibel gain amplifier to be the most common, let's analyze our errors with the corresponding value of Rfb.

Plot[{zInFcn[gm,330],20 Log[10,Abs[gainFcn[gm,330]]]},{gm,0.1,4},Frame->True,FrameLabel->{"gm","{Zin,Gain_db}"},PlotLabel->"Amplifier Finite gm Errors",GridLines->Automatic]

This amplifier will certainly work, given a finite gm. We must use bipolar transistors with gms greater than 1.0 to get good gain and terminal impedances. This translates to bias currents greater than 26 mA since gm is approximately ImA/26.

It is possible that the feedback resistors could be optimized for low-current operation, but this would have to be done on an as-needed basis. Also, we would expect the simple relationship between Rs and Rfb to be violated since the errors with gm show our input impedance increasing and our gain decreasing. This is because any increase in Rfb to compensate for gain reduction would also increase Zin and so not solve our error problem.

Conclusion

A procedure for designing a standard broadband amplifier has been created. Other engineers can follow the design development or use the design summary table. If devices are use at currents less than 26 mA, we can optimize the feedback resistors for best performance rather than just using the tabulated values.  Any errors in the table presumably get worse as gm is reduced and gain is increased.