Init

$url="https://docs.google.com/spreadsheet/pub?key=0An-lvWEXFqTvdElnLUNEOG5QTUJJaUh2aEpabUdIbEE&single=true&gid=0&output=csv";

raw=SemanticImport[$url]

There is a duplicate row where a billing error occurred:

raw[[10;;11]]

Exclude row from import:

med=SemanticImport[$url,ExcludedLines->{11}]

windowStr=ToString@StringForm["``-``",med[First,"date"]["Year"],med[Last,"date"]["Year"]]

season[d_DateObject]:=Which[
d["Month"]≥4&&d["Month"]≤9,"summer",
True,"winter"
]

Usage History

Show[
DateListPlot[med[All,{"date","elec ($)"}],PlotRange->Full,PlotLegends->SwatchLegend[{"electricity"}]],
DateListPlot[med[All,{"date","gas ($)"}],PlotRange->Full,PlotStyle->Lighter@Orange,PlotLegends->SwatchLegend[{"gas"}]],
PlotRange->{All,{0,200}},
PlotLabel->"Monthly Utilities Use, "<>windowStr,
FrameLabel->{None,"USD"},
ImageSize->500
]

Row[{
Histogram[med[All,"elec (kWh)"],{400,1800,50},PlotLabel->"Monthly kWh Distribution, "<>windowStr,
ImageSize->300
],
Histogram[med[All,"gas (therms)"],{0,200,5},PlotLabel->"Monthly therms Distribution, "<>windowStr,
ImageSize->300
]
}]

With[{
summer=Normal@med[Select[season[#date]==="summer"&]][All,"elec (kWh)"],
winter=Normal@med[Select[season[#date]==="winter"&]][All,"elec (kWh)"]
},
PairedHistogram[summer,winter,{0,1800,100},
PlotLabel->"Monthly kWh Distribution, summer vs. winter, "<>windowStr,
ChartLegends->{{"summer","winter"}},
ChartStyle->{24,None,None}
]
]

With[{
summer=Normal@med[Select[season[#date]==="summer"&]][All,"gas (therms)"],
winter=Normal@med[Select[season[#date]==="winter"&]][All,"gas (therms)"]
},
PairedHistogram[summer,winter,{0,200,10},
PlotLabel->"Monthly therms Distribution, summer vs. winter, "<>windowStr,
ChartLegends->{{"summer","winter"}},
ChartStyle->{24,None,None}
]
]

Forecasting

totaledSet=med[All,<|"date"->"date","sum"->(#["elec ($)"]+#["gas ($)"]&)|>]

Show[
DateListPlot[totaledSet[All,{"date","sum"}],PlotRange->Full,PlotLegends->SwatchLegend[{"electricity + gas"}]],
PlotLabel->"Monthly Utilities Use, Summed, "<>windowStr,
FrameLabel->{None,"USD"},
ImageSize->500
]

tsm=TimeSeriesModelFit[Normal@totaledSet[All,"sum"]];
ListLinePlot[{tsm["TemporalData"],Legended[TimeSeriesForecast[tsm,{12}],"12 month forecast"]},
PlotLabel->"Monthly Utilities Use, Summed, "<>windowStr
]

With[{yr=totaledSet[Last,"date"]["Year"],mo=totaledSet[Last,"date"]["Month"]},
Style[TableForm[
Table[
{
DatePlus[DateObject[{yr,mo},DateFormat->{"MonthNameShort"," ","Year"}],{i,"Month"}],
NumberForm[TimeSeriesForecast[tsm,i+1],{Infinity,2}]
},{i,0,6}
],
TableHeadings->{None,{"Month","Forecast ($)"}}
],FontFamily->"Verdana"]
]