Retrospective 
Asbestos Associated
 Mesothelioma Risk

James C. Rock, PhD, PE, CIH

Retired USAF, Retired Texas A&M University

For 2013 Wolfram Technology Conference, Oct 2013.       
      
Before showing Slide Show, Evaluate Notebook, Select Output Cell on Slide 3 & Hold Alt + {Click,Click}, ReSelect Output Cell + {Click, Click}.

Retrospective Asbestos Associated Mesothelioma Risk

Occupational Epidemiology, Toxicology and Physiology, show Meso Risk is a monotonic function of 5 variables

	int  = average intensity (concentration) of inhalation exposures in fibers/milliLiter (0 < int < 1000 f/mL)
	km = mesothelioma potency factor for type and dimensions of inhaled fibers (0.001 < km < 1000)
	dur = duration of each exposure in occupational years (1 occ yr = 2000 hours)
	lat  = latency or time since exposure began in calendar years
	p = power of exponential factor for latency in the Multistage Cancer Model

Retrospective Asbestos Associated Mesothelioma Risk

Asbestos is the fibrous form of a massive solid mineral
OSHA Regulated asbestos types are in either the serpentine or amphibole family

Serpentine, low mesothelioma risk from soft curved hollow scroll of magnesium silicate sheets
	Chrysotile - White Asbestos

Amphibole, high mesothelioma risk from long, thin needles of silicates with appreciable Fe, Ca, Al and some Mg
	Amosite  - Brown Asbestos
	Crocidolite - Blue Asbestos
	 Anthophyllite & Tremolite Asbestos are non commercial amphibole forms.

pH=;Style[Row[{Style[Column[{"White Chrysotile:  ","", "Brown Amosite:","", "Blue Crocidolite:"}],32,FontFamily->"Arial"],Show[pH,ImageSize->72 3.5]}],TextAlignment->"Center"]

http://www.mesotheliomasymptoms.com/sites/default/files/three%20types%20of%20asbestos.jpg

White Serpentine called Chrysotile Asbestos

Amosite - Needle Like Brown Fibers

Retrospective Asbestos Associated Mesothelioma Risk

A Mesothelioma is a Tumor growing in a membrane of flat cells called the Mesothelium

A Mesothelium is an antifriction membrane found where relative motion occurs
Parietal mesothelium covers body walls in chest (pleura) and abdomen (peritoneum)
Visceral mesothelium covers internal organs:  heart (pericardium), testes and vagina

General Multistage Environmental Carcinogen Model

Three main 'phases' for development of any cancer:

1. Initiation - Accumulation of genetic changes leading to partial
abrogation of growth control

2. Promotion - Clonal expansion of ‘initiated’ and partially uncontrolled cells.

3. Malignant Conversion - Acquisition of further genetic changes during clonal
expansion leading to one (or more) malignant cells

The Quantitative Model

For environmental agents (e.g., smoking, tiny fibers, benzene ... ); 
 
The instantaneous probability of Cancer is a function of: 
 				age = age at diagnosis, 	
 				x = age during exposure, and 	
 				p = # of causation stages:

Prob[x,age,p] ∝ int[x](((age-x-10))^(p-1))

Consider an exposure history, int[x], that starts at age t0 and ends at age t1, to carcinogen(s) of potency k[x]. 
Integrate to find the cumulative probability of cancer at age ≥ t1 + 10.

Prob[MesoDxd[age] |{ t0, t1, k[x ], int[x] }] 

= (∫_t0^t1)k[x] int[x](((age-x-10))^(p-1))dx

A Useful Closed Form Risk Model

Cumulative Probability of Mesothelioma when k and int are constants, age is age at diagnosis, 
t0 is the beginning and t1 ≤ age is the end of an exposure period.

Integrate[km int(((age - x - 10))^(p-1)),{x,t0,t1},Assumptions->{age>10,p>1}] =

((int k ((((-10+age-t0))^p)-(((-10+age-t1))^p)))/p)

Without loss of generality, set t0 =0 and measure both  from t0 for each exposure episode:   dur = t1 - t0 and lat = age - t0

Prob[MesoDxd[lat, dur] |{ k, int, p}] =

(k/p)int ((((lat -10))^p)-(((lat -dur -10))^p))

Numerical Model for Mesothelioma Probability

From Occupational Epidemiology and animal toxicology, current models of cancer development suggest:
    p ≈ 3 and  k/p ≈ km (10^(-10))  for chrysotile asbestos where km =1 for long chrysotile fibers (> 40 μm);
     km is larger for long amphibole fibers and smaller for shorter chrysotile fibers (< 40 μm).

int km (10^(-10)) ((((lat -10))^3)-(((lat -dur -10))^3)))

Price, B., and A. Ware :  "Mesothelioma: Risk Apportionment Among Asbestos Exposure Sources."  Risk Analysis 25 (4) : 937 - 943 (Aug 2005).

From Probability to Rate in Cases/Million

Given the Probability of Mesothelioma, find the number of cases expected in a cohort of 1 Million.

Rate in Mesos/Million = (10^6) * Prob[MesoDxd[lat, dur] | { km[x], int[x], p}]

Rate[MesoDxd[lat, dur]|{ km, int, p}] =

int km (10^(-4)) ((((lat -10))^3)-(((lat -dur -10))^3)))

This form useful for Epidemiologists, Industrial Hygienists and Risk Assessors.
For the rest of this presentation this rate is called the RISK of mesothelioma.
The equation is easily coded for use in Mathematica Demonstrations.

mr[{int_,dur_,lat_,km_,p_}] :=

((10^(-4)) km int)*(((lat-10)UnitStep[lat-10])^p -((lat-dur-10)UnitStep[lat-dur-10])^p )

Manipulate Allows Flexible Output Formats

Point Estimate
	Point Estimate of Meso Risk from a set of fixed input values

Parametric Plots
	Meso Risk plotted as a function of single variable with fixed values for other inputs
	
Extreme Value Estimate
	Range Estimate of Meso Risk from a set of ranges for input variables

Probability Density Function (PDF)
	Meso Risk PDF from Monte Carlo samples from PDFs for each input variable

Point Estimate of Mesothelioma Risk

Clear[int,dur,lat,km,p,i,d,l,k];
Manipulate[
Grid[
{{"Int","Dur","Lat","(Subscript[K, m])","Exponent","MesoRisk"},{"[f/mL]","[yr]","[yr]","[(Mesos/Million)/(f/mL)]","[1]","[Mesos/Million]"},NumberForm[{int,d,lat,k,p,mr[{int,d,lat,k,p}]},3]//Thread},
Dividers->{{False, False,False,False,False,True},{False,False, True, False}},
Spacings->{{2},{1,1,2,1}},
BaseStyle->{18, FontFamily->"Arial"}
],
{{int,2,Row[{"int"}]},.01,100,Appearance->"Labeled"},
{{d,12,"dur"},.01,50,Appearance->"Labeled"},
{{lat,30,"lat"},d,60,Appearance->"Labeled"},
{{k,2.5,"km"},0.014,800,Appearance->"Labeled"},
{{p,3},2,6,Appearance->"Labeled"},
"  ",
Style[mr[{"int","dur","lat","km","p"}],Bold,Black,24,FontFamily->"Arial",TextAlignment->"Center"],
LabelStyle->{24,Blue}
]

Mesothelioma Risk as a Function of Average Intensity

Manipulate[
Plot[mr[{int,du,la,km,p}],{int,0,30}, Frame->True,FrameLabel-> {"Average Intensity, f/mL","Meso Risk, Cases/Million"},
BaseStyle->{22, FontFamily->"Arial"},ImageSize-> 72 8],
(*{{int,2},0.01,30,,Appearance->"Labeled"},*)
{{du,10},0,40,Appearance->"Labeled"},
{{la,30},20,50,Appearance->"Labeled"},
{{km,2.5},0.01,1000,Appearance->"Labeled"},
{{p,3},3,4,Appearance->"Labeled"},
"  ",
Style[mr[{Style["int",Blue],"du","la","km","p"}],Bold,Black,24,FontFamily->"Arial"],
LabelStyle->{24,Blue}]

Mesothelioma Rate as a Function of Exposure Duration

Manipulate[
Plot[mr[{int,du,la,km,p}],{du,0,30}, Frame->True,FrameLabel-> {"Exposure Duration, Occupational Yr","Meso Risk, Cases/Million"},
BaseStyle->{18, FontFamily->"Arial"},ImageSize-> 72 9],
{{int,2},0.01,30,Appearance->"Labeled"},
(*{{du,10},0,40,Appearance->"Labeled"},*)
{{la,30},20,50,Appearance->"Labeled"},
{{km,2.5},0.01,1000,Appearance->"Labeled"},
{{p,3},3,4,Appearance->"Labeled"},
"  ",
Style[mr[{"int",Style["du",Blue],"la","km","p"}],Bold,Black,24,FontFamily->"Arial"],
LabelStyle->{24,Blue}]

Mesothelioma Rate as a Function of Latency

Manipulate[
Plot[mr[{int,du,la,km,p}],{la,10,40}, Frame->True,
FrameLabel-> {"Latency, Calendar Yr","Meso Risk, Cases/Million"},
BaseStyle->{18, FontFamily->"Arial"},ImageSize-> 72 9],
{{int,2},0.01,30,Appearance->"Labeled"},
{{du,10},0,40,Appearance->"Labeled"},
(*{{la,30},20,50,Appearance->"Labeled"},*)
{{km,2.5},0.01,1000,Appearance->"Labeled"} ,
{{p,3},3,4,Appearance->"Labeled"},
"  ",
Style[mr[{"int","du",Style["la",Blue],"km","p"}],Bold,Black,24,FontFamily->"Arial"],
LabelStyle->{24,Blue}]

Mesothelioma Rate as a function of Potency Factor

Manipulate[
Plot[mr[{int,du,la,km,p}],{km,0.01,100}, Frame->True,FrameLabel-> {"Normalized Potency Factor, Km","Meso Risk, Cases/Million"},
BaseStyle->{18, FontFamily->"Arial"},ImageSize-> 72 9],
{{int,2},0.01,30,Appearance->"Labeled"},
{{du,10},0,40,Appearance->"Labeled"},
{{la,30},20,50,Appearance->"Labeled"},
(*{{km,2.5},0.01,1000,Appearance->"Labeled"},*)
{{p,3},3,4,Appearance->"Labeled"},
"  ",
Style[mr[{"int","du","la",Style["km",Blue],"p"}],Bold,Black,24,FontFamily->"Arial"],
LabelStyle->{24,Blue}]

Mesothelioma Rate as a function of Number of Stages

Manipulate[
Plot[mr[{int,du,la,km,p}],{p,2,4}, Frame->True,FrameLabel-> {"Exponent p, Number of Stages in Mesothelioma Model","Meso Risk, Cases/Million"},
BaseStyle->{18, FontFamily->"Arial"},ImageSize-> 72  9],
{{int,2},0.01,30,Appearance->"Labeled"},
{{du,10},0,40,Appearance->"Labeled"},
{{la,30},20,50,Appearance->"Labeled"},
{{km,2.5},0.01,1000,Appearance->"Labeled"} (*,
{{p,3},3,4,Appearance->"Labeled"}*),
"  ",
Style[mr[{"int","du","lat","km",Style["p",Blue]}],Bold,Black,24,FontFamily->"Arial"],
LabelStyle->{24,Blue}]

Extreme Value Estimate of Mesothelioma Risk Range

Here each input variable is assigned a range and the Risk estimate is presented as a Uniform PDF.

Manipulate[
Column[{

Grid[
{{"Int","Dur","Lat","(Subscript[K, m])","Exponent","MesoRisk"},{"(f/mL)","(yr)","(yr)","(((Mesos/Million)/(f/mL)))","(1)","(Mesos/Million)"},
{NumberForm[{(2^log2int),(2^log2inthi)},2],
NumberForm[{d,dhi},3],
NumberForm[{lat,lathi},3],
NumberForm[{(2^log2k),(2^log2khi)},3],
NumberForm[{p,phi},3],
NumberForm[{lo,hi}=mr[{{(2^log2int),(2^log2inthi)},{d,dhi},{lat,lathi},{(2^log2k),(2^log2khi)},{p,phi}}],3]}},
Dividers->{{False, False,False,False,False,True},{False,False, True, False}},
Spacings->{{2},{1,1,2,1}},
BaseStyle->{18, FontFamily->"Arial"}],
" "," ",
Labeled[
Plot[PDF[UniformDistribution[{lo,hi}],x],{x,0,1.1 hi},PlotRange->All,Frame->True,
BaseStyle->{24, FontFamily->"Arial",Bold},ImageSize-> 6 72,
FrameLabel->{"MesoRisk in Mesos/Million","ExtremeValue PDF"},
Filling->0],
Style["Extreme Value PDF for Meso Risk",{24, FontFamily->"Arial",Blue,Bold}]]
}]
,
{{log2int,1,"(Subscript[Log, 2])[int]"},-6,9,1.,Appearance->{"Labeled"}},
{{log2inthi,3,"(Subscript[Log, 2])[intHi]"},log2int+.5,9,1,Appearance->"Labeled"},
{{d,12,"dur"},.01,40,Appearance->"Labeled"},
{{dhi,13,"durHi"},d,40,Appearance->"Labeled"},
{{lat,30,"lat"},d,60,2,Appearance->"Labeled"},
{{lathi,40,"latHi"},lat,60,2,Appearance->"Labeled"},
{{log2k,1.,"(Subscript[Log, 2])[km]"},-6,10,1,Appearance->"Labeled"},
{{log2khi,4,"(Subscript[Log, 2])[kmHi]"},log2k,10,1,Appearance->"Labeled"},
{{p,2.9},2,6,.5,Appearance->"Labeled"},
{{phi,3.1,"pHi"},p,6,.5,Appearance->"Labeled"},

LabelStyle->{24,Blue}]

PDF of Meso Risk when all Input Variables are Uniformly Distributed

Here each input variable is sampled repeatedly from its Uniform Distribution.
Meso Risk is accumulated as a Vector and interpreted in a Monte Carlo way.
The resulting Risk estimate PDF is presented as a histogram and as a SmoothKernelDistribution.

Off[NumberForm::sigz]
Manipulate[
{SeedRandom[seed] ;(* Allows repeated execution with same numbers for debugging *)
in={(2^log2int),(2^log2inthi)}, du={d,dhi},la={lat,lathi},km={(2^log2k),(2^log2khi)},pe={p,phi},
mrEV={mrN,mrX}=mr[{in,du,la,km,pe}],
vn=Table[{RandomReal[in],RandomReal[du],RandomReal[la],RandomReal[km],RandomReal[pe]},{nn,1,nx}];
mrn=mr[vn]//Thread ;(* Calculates Meso Risk for each of n values of the vector vn *) 
dist=SmoothKernelDistribution[mrn];(* Finds an interpolation function for the PDF *)
hist=HistogramDistribution[mrn] (* Unit Area Histogram of mrn data, ~PDF *),
{x0,lo,med,hi,x1}=Quantile[hist,{.01,qlo,.5,(1-qlo),.99}] (* Finds 1st, lo[qlo], 50th, hi[qlo] and 99th %ile from vector of nx mr values *),
" "," "
};

Column[{

Framed[Grid[
{{"Int","Dur","Lat","(Subscript[K, m])","Exponent","MesoRisk"},{"(f/mL)","(yr)","(yr)","(((Mesos/Million)/(f/mL)))","(1)","(Mesos/Million)"},

{in,NumberForm[du,3],NumberForm[la,3],NumberForm[km,3],NumberForm[pe,3],NumberForm[mrEV,3]}},
Dividers->{{False, False,False,False,False,True},{False,False, True, False}},
Spacings->{{1},{.5,.5,1,.5}},
BaseStyle->{16,Bold, FontFamily->"Arial"}],FrameMargins->4,RoundingRadius->10],


(*Labeled[*)
Plot[PDF[UniformDistribution[mrEV],x],{x,0,1.05mrX},PlotRange->All,Frame->True,
BaseStyle->{18, FontFamily->"Arial",Bold},ImageSize-> 72 6,FrameLabel->{" ","ExtremeValue PDF"},
Filling->0],
(*Style["Extreme Value PDF for Meso Risk",{24, FontFamily->"Arial",Blue,Bold}]],*)


Show[
{Plot[PDF[hist,x],{x,0,1.05 mrX},PlotStyle->{Thick,Black},BaseStyle-> {18,Bold,FontFamily->"Arial"},
FrameLabel->{"Meso Risk , cases/Million","Probability Density (PDF)"},Frame->True,ImageSize-> 72 6],
Plot[PDF[dist,x],{x,0,mrX},PlotStyle->Thick],
Plot[PDF[dist,x],{x,lo,hi},Filling->0]
}
],

Row[{"         ",
Style[
Framed[Grid[
{{"Proportion",0.01,qlo,0.5,(1-qlo),0.99},
NumberForm[{"Quantile",x0,lo,med,hi,x1},3]//Thread}
],FrameMargins->4, RoundingRadius->10,Alignment->Center],
18,FontFamily->"Arial"]
}]
}],
" ", " "," "," ",
{{nx,256,"nx = # of MC"},{128,256,512,1024,2048,4096,8192,16384}},
{{qlo,.05,"qlo = TailArea"},0.025,0.3,.025,Appearance->"Labeled"},
{{seed,13,"RandomSeed"},7,97,3,Appearance->"Labeled"},
{{log2int,1,"(Subscript[Log, 2])[int]"},-6,9,1.,Appearance->"Labeled"},
{{log2inthi,3,"(Subscript[Log, 2])[intHi]"},log2int+.5,9,1,Appearance->"Labeled"},
{{d,12,"dur"},.01,40,Appearance->"Labeled"},
{{dhi,13,"durHi"},d,40,Appearance->"Labeled"},
{{lat,30,"lat"},d,60,2,Appearance->"Labeled"},
{{lathi,40,"latHi"},lat,60,2,Appearance->"Labeled"},
{{log2k,1,"(Subscript[Log, 2])[km]"},-6,10,1,Appearance->"Labeled"},
{{log2khi,4,"(Subscript[Log, 2])[kmHi]"},log2k,10,1,Appearance->"Labeled"},
{{p,2.9},2,4,.2,Appearance->"Labeled"},
{{phi,3.1,"pHi"},p,4,.2,Appearance->"Labeled"},

LabelStyle->{18,Blue}]

Are There Any Questions?

Thank you for your Attention.

JAMES C. ROCK

Appendix - Extra Slide

The occupationial exposure factors to be estimated include 
	inhalation of dangerous concentrations of asbestos fibers, called intensity, int
	of the type and size that are potenty for mesothelioma, km
	over sufficiently long cumulative durations, dur 
	with a sufficiently long latency between exposure and diagnosis,lat

Substitution:  lat and dur measured from t0 for age and t1 measured from t0

(-10 + age - t1) /. {age -> lat + t0, t1 -> dur + t0}

 lat - dur - 10

Questions
	1.  Evaluate so that code is hidden and manipulate is shown in each slide
	
	2.  Why in Printpreview of 22 slide slideshow in working view, are there hundreds of pages as it recycles?
  	
  	3.  Why in Printpreview of 22 slide slideshow in slideshow view, do slides have page breaks in the middle of graphics?
    	
    	4. If I make a pdf file is too large to email and page breaks do occur in middle of graphics.
    	
    	5. I need a powerpoint version ... is there a converter from nb to ppt?
  	
  	6. Difference between Presentation and Slideshow screen modes?