A Financial Model of Medication Wastage Avoidance 
by Using Genetic Testing

Susan B. Garavaglia, PhD, MBA

Medco Health Services, Inc., Franklin Lakes, New Jersey

Abstract

No medication is 100% effective for 100% of patients.  With certain chronic diseases, such as depression and rheumatoid arthritis, the patient may not be aware that the medication is not helping him or her and use non-efficacious medications for several years.  Thus, the medication is a wasted cost.  Spear, et. al. (1) produced a meta-analysis of efficacy of drugs for 14 diseases and, more recently, Kitzmiller, et. al. (5) provides a useful overview of current knowledge of pharmacogenomics.  In several therapeutic areas, the value of genetic testing or genotyping has been demonstrated in enabling better clinical outcomes and lower medical costs.(2,3,4)   In some cases, genotyping establishes a phenotype of metabolization rates and, in other cases, genotyping leads the prescriber to the right drug for the patient versus a non-efficacious or even toxic drug.  A genetic test needs to be performed only once on a patient; however, to identify the subgroup of patients that require adjustments to therapy or dosage, all patients must be tested, creating a cost barrier to testing.   An interactive model is introduced to estimate how much wasted medication could be avoided with an effective genetic test.  Selectable parameters include disease of interest,  patient population size, inflation rates, nominal improvement percent, and cost per test.   Model also has hard-coded parameters which could be modified, such as Average Wholesale Price (AWP)  Per Member Per Year (PMPY) costs and total enrollment.  Medication spend and wastage are calculated as annuities.  Mathematica functions used include Manipulate, PieChart, TimeValue, and Annuity.

Background

Wastage in Prescription Medication

Patients do not take medication as prescribed and receive no benefit

Patients switch medication with leftover old medication on hand

Patient is prescribed medication that is inappropriate or inefficacious

Insurers and other payers hate medication wastage!!!

Medication Efficacy and Costs

The table below uses the efficacy data from Spear et. al. (1) and Average Wholesale Price of all the drugs in the therapeutic class.  The cost is based on per member (covered beneficiary) per year (PMPY) calculations which are standard for the industry.

TableForm[Prepend[EfficacyTable,{"Disease","Efficacy %","AWP PMPY"}]]

Medication Cost as an annuity stream

The model calculates the total cost of three years of efficacious medication including inflation with and without the use of genetic test results.  The model user can select a different inflation rate for up to three years and a nominal percent improvement in efficacy.

drugtrend1=3.7;
drugtrend2=3.7;
drugtrend3 = 3.7;
withouttest = Table[TimeValue[Annuity[(allPMPY* totalpop)*notesteff,x],{drugtrend1,drugtrend2,drugtrend3}/100,x],{x,1,3}][[3]];
withgentest = Table[TimeValue[Annuity[(allPMPY* totalpop)*alleffimprove,x],{drugtrend1,drugtrend2,drugtrend3}/100,x],{x,1,3}][[3]];
AccountingForm[N[withouttest],DigitBlock-> 3]
AccountingForm[N[withgentest],DigitBlock-> 3]

Program and Results

EfficacyTable = {{"Alzheimer's", 30, 31.07}, 
    {"Analgesics(Cox-2)", 80, 10.}, {"Asthma/COPD", 60, 84.67}, 
    {"Cardiac Arrythmias", 60, 7.13}, {"Chronic Pain", 20, 31.31}, 
    {"Depression(SSRI's)", 62, 56.64}, {"Diabetes (Type 2)", 57, 
     69.93}, {"Hepatitis C", 47, 1.07}, {"Incontinence", 40, 
     10.73}, {"Migraine (acute)", 52, 14.}, 
    {"Migraine (Prophylaxis)", 50, 14.}, {"Oncology", 25, 26.07}, 
    {"Osteoporosis", 48, 23.73}, {"Rheumatoid Arthritis", 50, 44.}, 
    {"Schizophrenia", 60, 32.8}}; 
totalpop = 69873466; 
titlecolor = ColorData["Crayola", "MidnightBlue"]; 
costcolors = {ColorData["Crayola", "JungleGreen"], 
    ColorData["Crayola", "OrangeYellow"], ColorData["Crayola", 
     "MagicMint"]}; 
improvcolors = {ColorData["Crayola", "JungleGreen"], 
    ColorData["Crayola", "Salmon"], ColorData["Crayola", 
     "MagicMint"]};

Manipulate[
DynamicModule[
{efficacy = Position[StringCases[EfficacyTable[[All,1]],selecteff] ,selecteff][[1,1]]},
(* Basic Model *)
(* Initialize Parms *)
If[nomimpr+ EfficacyTable[[efficacy,2]] > 100, nomimpr = 100 - EfficacyTable[[efficacy,2]] ];
allPMPY =EfficacyTable[[efficacy,3]];
notesteff = 1 - EfficacyTable[[efficacy,2]]/100;
nomimprpct = nomimpr/100;
alleffimprove = 1 - EfficacyTable[[efficacy,2]]/100- nomimprpct;
(* Annuities *)
 withouttest = Table[TimeValue[Annuity[(allPMPY* totalpop)*notesteff,x],{drugtrend1,drugtrend2,drugtrend3}/100,x],{x,1,3}][[3]];
withgentest = Table[TimeValue[Annuity[(allPMPY* totalpop)*alleffimprove,x],{drugtrend1,drugtrend2,drugtrend3}/100,x],{x,1,3}][[3]];
totaltestcost = numpats * gtestcost;
opportunity = withouttest-withgentest - totaltestcost;
slicestyle = Style[#,Bold,12,FontFamily -> "Arial"]&/@{"Baseline Efficacy","Test Costs","Avoided Waste"};
nicenums = IntegerPart[{withgentest,totaltestcost,opportunity}];
slabel = Style[#,Bold,12,FontFamily -> "Arial"]&/@{"Efficacy %","Non-efficacy %","Nom. Improvment %"};
Labeled[
GraphicsRow[{
AccountingForm[PieChart[nicenums,LabelingFunction-> (Placed[Style[#1,16,Bold],"RadialCenter"]&),ChartLegends ->Placed[slicestyle,Bottom],LegendAppearance -> Row,
Epilog -> Text [Style["Drug Costs",Bold,20,FontFamily -> "Arial",ColorData["Crayola","LaserLemon"]]],ImageSize -> Medium,
ChartStyle-> costcolors],DigitBlock -> 3],
PieChart[
IntegerPart[{{1-notesteff,notesteff}*100,{1-alleffimprove-nomimprpct,notesteff-nomimprpct,nomimprpct}*100}],LabelingFunction-> (Placed[Style[#1,16,Bold],"RadialCenter"]&),
ChartStyle-> improvcolors,ChartLegends -> Placed[slabel,Bottom],LegendAppearance -> Row,Epilog ->{ Text [Style["Without Test",Bold,20,FontFamily -> "Arial",ColorData["Crayola","LaserLemon"]]],Inset[Style["With Test",20,FontFamily -> "Arial",ColorData["Crayola","Maroon"]],Offset[{80,90},{0,0}]]},ImageSize -> Medium]},
Frame -> All,ImageSize -> {{900,400},{900,400}}
],

Style["Model of Wasted Therapy Avoidance with Genetic Testing",titlecolor,Bold,22,FontFamily-> "Arial"],Top]
],

Row[{Style["Variable Parameters  ",Bold,FontFamily -> Arial, 12],"(Mouseover Name for Details)"}],
Delimiter,
{{selecteff,"Alzheimer's",Tooltip["Disease ","Disease or Therapeutic Class"]},EfficacyTable[[All,1]],ControlType->PopupMenu},
{{drugtrend1,3.7,Tooltip["Drug Trend Yr. 1","Overall or Individual Class Trend 0 to 25%"]},0,25,.01,Appearance ->"Labeled"},
{{drugtrend2,3.7,"Drug Trend Yr. 2"},0,25,.01,Appearance ->"Labeled"},
{{drugtrend3,3.7,"Drug Trend Yr. 3"},0,25,.01,Appearance ->"Labeled"},
{{gtestcost,350,Tooltip["Genetic Test Cost","$100-$500 Range"]},100,500,25,Appearance -> "Labeled"},
{{nomimpr,5,Tooltip["Nominal Improvement %",Grid[{{"Additional Percentage Points of Response"},{ "Truncated to sum to 100% Max"}}]]},1,100,1,Appearance -> "Labeled"},
{{numpats,100000,"Number of Patients"},"Number of Patients",ControlType-> InputField },
SynchronousUpdating -> False,ControlPlacement -> Bottom, SaveDefinitions -> True
]

Limitations of Application

Model uses costs for overall therapy class; it’s possible to enhance model to be drug-specific.

Downstream medical costs, which are not included,  may underestimate total cost of ineffective therapy.

A genetic test may reveal that the optimal treatment is more expensive than the current treatment.

Certain parameter values create overlapping display values.

The wastage is more of an opportunity cost than true savings.

References

(1) Spear, Brian B, Margo Heath-Chiozzi, and Jeffery Huff, Clinical Applications of Pharmacogenetics, Trends in Molecular Medicine, Vol. 7, No. 5, May 2001

(2) Epstein, Robert S., MD, MS, Thomas P. Moyer, PHD, Ronald E. Aubert, PHD, Dennis J. O’Kane, PHD, Fang Xia, PHD, Robert R. Verbrugge, PHD, Brian F. Gage, MD, MS, J. Russell Teagarden, DMH, RPH, Warfarin Genotyping Reduces Hospitalization Rates Results From the MM-WES (Medco-Mayo Warfarin Effectiveness Study), Journal of the American College of Cardiology, Vol. 55, No. 25, 2010

(3) Schroth, Werner, Matthew P. Goetz, Ute Hamann, Peter A. Fasching, Marcus Schmidt, Stefan Winter, Peter Fritz, Wolfgang Simon, Vera J. Suman, Matthew M. Ames, Stephanie L. Safgren, Mary J. Kuffel, ·Hans Ulrich Ulmer, Julia Boländer, Reiner Strick, Matthias W. Beckmann, Heinz Koelbl, Richard M. Weinshilboum, James N. Ingle, Michel Eichelbaum, Matthias Schwab, ·	Hiltrud Brauch, Association Between CYP2D6 Polymorphisms and Outcomes Among Women With Early Stage Breast Cancer Treated With Tamoxifen, JAMA. 2009;302(13):1429-1436.

(4) Kreutz RP, Stanek EJ, Aubert R, Yao J, Breall JA, Desta Z, Skaar TC, Teagarden JR, Frueh FW, Epstein RS, Flockhart DA. Impact of proton pump inhibitors on the effectiveness of clopidogrel after coronary stent placement: the clopidogrel Medco outcomes study. Pharmacotherapy. 2010 Aug;30(8):787-96. 

(5) Kitzmiller, Joseph P., David K. Groen, Mitch A. Phelps, Wolfgang Sadee, Pharmacogenomic testing: Relevance in medical practice (Why drugs work in some patient but not in others), Cleveland Clinic Journal of Medicine, Vol. 78, No. 4 2011 April. 243-257.