PolarizationB

Version 2.1
Part two of a two part NoteBook
2/25/92
Frank Hastings and John Schneider

Circular Polarization

When Etotal has circular polarization, the tip of its electric field vector will trace out a circular path in the h-v plane.  In order for this to occur the magnitudes of E1 and E2 must be equal, and the phase difference between the component waves must be ±p/2.   The phase difference can be expressed by representing one component as a sine wave and the other as a cosine, since sines and cosines are 90° out of phase.  For example
         
     Etotal = ×h E1 cos(wt ± bd ± p/2)  +  ×v E1 cos(wt ± bd)                     (4)
              = ×h E1 sin(wt ± bd) +  ×v E1 cos(wt ± bd)
     
   Equation (4) shows that Etotal will maintain a constant magnitude;  as one component goes to zero, the other component grows to its largest value.   This idea is illustrated in parts (a) and (b) of Fig. 5.  Figure 5a explicitly shows each of the components in Etotal as a function of position.  It can be animated to show the variation of the field as a function of time.  The values of the electric field are highlighted at the point bd=p/2 for the sake of illustration.  By slowly stepping through the animation, it should be apparent that at the point bd=p/2 the sum of the components will always be equal to a fixed value.  In Fig. 5b a frontal view is used to show the components along with the resultant, Etotal.  It is clear that Etotal's fixed magnitude results in a circular path.  Figure 5c provides a three dimensional represtation of the electric field as a function of time.  The animations in 5b and 5c assume that time starts at t=0 and fields are being evaluated at d=0.

showWaves[(*phase1*) -Pi/2, (*phase2*) 0]

(a)

rotatingField[1,1,-Pi/2,0]

(b)

rotatingField3D[1,1,-Pi/2,0]

(c)

Fig.2 Represetations of circular polarization.

Elliptical Polarization

Elliptical polarization is the most general of the three.   Linear and circular polarization are actually degenerate forms of elliptical polarization.  Consider the general equation
     
     Etotal = ×h E1 cos(wt + bd + f1)  +  ×v E2  cos(wt + bd + f2)		(5)
                       
The difference between the phases can be any value between 0 and 2p.  Except for the special cases given in the previous two sections(multiples of p for the linear case and ±p/2 for the circular case), all other phase differences cause Etotal to be elliptically polarized.  This means that the tip of the electric field vector will trace an elliptical path in the h-v plane.

   In the following cell the function ellipse is given.   This function gives output similar to what you have already seen except it does not generate an entire animated sequence.  This function provides a quick means to examine a number of different combinations of magnitudes and phases.   The relationship between the different polarizations can be emphasized by selecting  phase differences close to 0°, 90°, and 180°.  Notice that the ellipse will slowly take on a linear or a circular shape as the phase difference approaches the appropriate value.  [Note:  Angles must be entered in radians.]

ellipse[(*E1*) 2, (*E2*) 4,0 (*phase1*), (*phase2*) 4.5]

Initialization Cells

Off[General::spell1]

Clear[showWaves]
showWaves[p1_, p2_]:=
Block[{t, d, delta, pi, axes, e1wave, e2wave},
   pi = N[Pi];
   delta = pi/12;
   Do[e1wave = Table[Line[{{d, 7 + 4 Cos[t - d + p1]},
                    {d+delta, 7 + 4 Cos[t - d - delta + p1]}}], 
                    {d, 0, 2 pi, delta}]; 
      e2wave = Table[Line[{{d, -7 + 4 Cos[t - d + p2]},
                    {d+delta, -7 + 4 Cos[t - d - delta + p2]}}],
                    {d, 0, 2 pi, delta}];
      axes = {Line[{{0,7}, {7,7}}],
              Line[{{0,-7}, {7,-7}}],
              {Dashing[{0.01, 0.01}],
              Line[{{1.57,-12.5}, {1.57,7}}]}, 
              Text["h, E1",{-.25,7}, {1,0}],
              Text["v, E2",{-.25,-7}, {1,0}],
              Text["(beta)d=Pi/2", {1.4,-12.5}, {1,0}],
              PointSize[0.02],
              Point[{pi/2, 7 + 4 Cos[-pi/2 + t + p1]}],
              Point[{pi/2, -7 + 4 Cos[-pi/2 + t + p2]}],
              {Thickness[0.008],
              Line[{{pi/2, 7}, {pi/2, 7 + 4 Cos[-pi/2 + t + p1]}}],
              Line[{{pi/2, -7}, {pi/2, -7 + 4 Cos[-pi/2 + t + p2]}}]}};
      Show[Graphics[{e1wave, e2wave, axes}],
         Axes -> None,
         PlotRange -> {{-3,7}, {-13,11.5}}],
         {t, 0, 2 pi, delta}]
     ]

Clear[rotatingField];
rotatingField[mag1_, mag2_, phase1_, phase2_]:=
Block[{vector, ellipse}, 
   ellipse =  Line[Table[{mag1 Cos[t+phase1],mag2 Cos[t+phase2]},{t,0,2 Pi,Pi/25}]];
   Do[vector = {Thickness[0.01],  PointSize[0.03],
        Line[{{0, 0},
              {mag1 Cos[t+phase1],mag2 Cos[t+phase2]}}],
        Point[{mag1 Cos[t+phase1], mag2 Cos[t+phase2]}],
        Line[{{0, 0},
              {0, mag2 Cos[t+phase2]}}],
        Line[{{0,0}, 
              {mag1 Cos[t+phase1], 0}}], 
        Point[{mag1 Cos[t+phase1], 0}], 
        Point[{0, mag2 Cos[t+phase2]}]};
      Show[Graphics[{vector, ellipse}],
           AxesLabel->{"h,(V/m)", "v,(V/m)"},
           PlotRange -> {{-1.05 mag1, 1.05 mag1}, {-1.05 mag2, 1.05 mag2}},
           AspectRatio -> Automatic,
           Axes->Automatic],
     {t, 0, 2Pi, Pi/15}]
]

rotatingField3D::usage = 
"wave3D[magnitudeX_, magnitudeY_, phaseX_, phaseY_] a sixty frame
animation of Etotal as a function of time."

Clear[rotatingField3D];
rotatingField3D[mag1_, mag2_, phase1_, phase2_] :=
Block[{axes, max, point, pi, time},
   pi = N[Pi];
   max = Max[mag1,mag2];
   delta = pi/15;
   axes = {Line[{{0,0,0}, {20,0,0}}],
           Line[{{0,-5,0}, {0,5,0}}],
           Line[{{0,0,-5}, {0,0,5}}]};
   filler[-1] = { };
   Do[filler[time] = Flatten[{filler[time-1],
         Polygon[{{time delta,0,0},
               {(time+1) delta,0,0},
               {(time+1) delta,
                mag1 Cos[(time+1) delta + phase1], 
                mag2 Cos[(time+1) delta + phase2]},
               {time delta,
                mag1 Cos[time delta + phase1],
                mag2 Cos[time delta + phase2]}}]}];
       point = {PointSize[0.03],
               Point[{(time+1) delta ,
                      mag1 Cos[(time+1) delta + phase1],
                      mag2 Cos[(time+1) delta + phase2]}]};
      Show[Graphics3D[{axes, filler[time], point},
         BoxRatios -> {2,1,1}],
         PlotRange -> {{0, 4 pi},{-max,max},{-max,max}},
         Axes -> True,
         Ticks -> None,
         AxesLabel->{"time", "h", "v"},            
         AspectRatio -> Automatic],
      {time, 0, 60}]
 ]

Clear[ellipse];
ellipse[mag1_,mag2_,phase1_,phase2_] :=
Block[{time, skip, pi, max, filler, axes},
   pi = N[Pi];
   delta = pi/15;
   max = Max[mag1,mag2];
   ParametricPlot[{mag1 Cos[skip + phase1],
                   mag2 Cos[skip + phase2]}, {skip, 0, 2 pi},
      Axes -> True,
      AxesLabel -> {"h,(V/m)", "v,(V/m)"},
      AspectRatio -> Automatic];
   filler = Table[Polygon[{{time,0,0},
          {time+delta,0,0},
          {time+delta, mag1 Cos[time+delta+phase1], 
            mag2 Cos[time+delta+phase2]},
          {time, mag1 Cos[time+phase1], mag2 Cos[time+phase2]}}],
       {time, 0, 4 pi, delta}];
   axes = {Line[{{0,0,0}, {20,0,0}}],
           Line[{{0,-5,0}, {0,5,0}}],
           Line[{{0,0,-5}, {0,0,5}}]};
   Show[Graphics3D[{axes, filler}],
      BoxRatios->{2,1,1}, 
      PlotRange->{{0,4 pi},{-max,max},{-max,max}},
      Axes -> True,
      Ticks -> None,
      AxesLabel->{"time", "h", "v"}]
]

On[General::spell1]