PolarizationA

Version 2.3
(Part A of a two part NoteBook)
2/25/92
Frank Hastings and John Schneider

Introduction

As two plane waves propagate in the same direction, the magnitude and orientation of the resultant electric field may change.  Polarization is defined as the orientation of the electric field at a given point and it can vary in a number of ways.
    
   Consider a source that generates two plane waves that propagate in the same direction, but the electric field of one wave is oriented horizontally while the other is vertical.  Suppose, also, that the waves have identical frequencies, but they have different phases and magnitudes.  These waves can be represented by
      
     E1 = ×h E1 cos(wt ± bd + f1 ) 						(1a)
     E2 = ×v E2 cos(wt ± bd + f2 ) 						(1b)
         
In this NoteBook bold face is used to represent vectors, and × represents unit vectors.   The unit vectors ×h and ×v stand for the horizontal and vertical directions.   E1  and E2 (not bold) are real magnitudes, d gives the position in the direction of propagation, while w and b are the angular frequency and the phase constant respectively.  One possible realization of E1 and E2 is illustrated in Fig. 1.  Here the magnitude and phase for the horizontal component are 3 and 0, and for the vertical component they are 2 and p/2.  (The commands are defined in the Initialization section at the end of this NoteBook.)

twoWaves[(*E1*) 3, (*E2*) 2, (*p1*) 0, (*p2*) Pi/2]

Fig.1   Vertical and horizontal components of the electric field.

The total field is the sum of the vectors in (1):
               
Etotal = E1 + E2									(2)
           
Consider what would happen if the position d was fixed, and time was allowed to vary.  The behavior of Etotal  depends on the magnitudes and phases of  E1 and E2 and will vary over a path that is either a line, a circle or an ellipse.  

   Figure 2, gives some examples that show Etotal at the fixed position d=0.  The graphics can be animated to show Etotal changing with time.  The graphics in Fig. 2 can also be used to illustrate the idea of right-hand and left-hand polarization.   Figure 2b shows a left-rotating field while Fig. 2c shows a right-rotating one.  If the thumb of the right hand is placed in the direction of propagation (pointing out of the screen in Fig. 2) , and the fingers curl in the direction of spin, the wave is said to be right-hand polarized.  Rotation in the opposite direction is left polarization.

Linear polarization.
 Etotal =  ×h 4 cos(wt) + ×v 2 cos(wt + p)

rotatingField[(*E1*) 4, (*E2*) 2, (*phase1*) 0, (*phase2*) Pi]

(a)

Left circular polarization.
 Etotal =  ×h 4 cos(wt) + ×v 4 cos(wt + p/2)

rotatingField[(*E1*) 4, (*E2*) 4, (*phase1*) 0, (*phase2*) Pi/2]

(b)

Right elliptical polarization.
 Etotal =  ×h 4 cos(wt) +  ×v 2 cos(wt ± 3.00)

rotatingField[(*E1*) 4, (*E2*) 2, (*phase1*) 0, (*phase2*) -2.0]

(c)
                    
Fig.2  (a)  Etotal when f1 = f2.  (b)  Etotal when E1 = E2 and f2 ± f1 = 90°. (c)  Etotal when E1 = 4, E2 = 2, f1 = 90°, and f2 = ±2.0 (rads).

Linear Polarization

The vector fields in Eq. (1) can be combined to produce an  Etotal  that changes only in magnitude and not direction.  These waves are said to be linearly polarized and an example was given in Fig. 2a.  A wave is linearly polarized when its constituent waves are either in phase, or out of phase by an integer multiple of p.  Even integer multiples of p will place the field vector's line of travel in the first and third quadrants, while odd multiples will place it in the second and fourth (see Fig. 3).  If the magnitudes of the component waves are changed, a change in the slope of the line of travel will occur.  The linearly polarized wave can be written
        
 Etotal  =  ×h E1 cos(wt ± bd + f1 ) + ×v  E2 cos(wt ± bd + (f1  + n p))		(3)

(a)

(b)
Fig.3  (a) Orientation of  Etotal  for phase differences equal to odd
integer multiples of p.  (b) Orientation of  Etotal  for phase 
differences equal to even integer multiples of p.

Figure 4 shows two views of the wave.  Figure 4a presents a frontal view of the wave, looking down the direction of propagation.   It shows the magnitude and direction of the electric field, and it includes the constituent waves.  This can be animated to show the variation as a function of time.  Figure 4b also shows Etotal changing as a function of time, but it provides a three-dimensional representation.  Keep in mind that both these plots show the variation of the electric field at a fixed point in space.  The unit vector ×k is used to indicate the direction of propagation.

Linear polarization.
 Etotal =  ×h 4 cos(wt) + ×v 2 cos(wt + p)

rotatingField[(*E1*) 4, (*E2*) 3, (*phase1*) 0, (*phase2*) 0]

(a)

rotatingField3D[(*E1*) 4, (*E2*) 3, (*phase1*) 0, (*phase2*) 0]

(b)

Fig 1: (a) Frontal view of the wave showing the Etotal  and its components. (b) Three-dimensional view of the same wave.

The graphics above show equation (3) for only one linear case.  It may be helpful to see the effect of varying the magnitudes and phases of the component waves.  Feel free to vary the parameters given in the Mathematica commands.  They can handle any combination of magnitudes and phases (just keep in mind that magnitudes are always non-negative).  However, be forewarned that some of these animations take a while to generate since there are so many frames.

Initialization Cells

Off[General::spell1]

(* This commands shows the relationship between the two
   cross polarized fields *)
twoWaves[e1_, e2_, phase1_, phase2_]:=
Block[{axes, delta=0.4, max, mag1, mag2, omega=1, t, waveh, wavev},
   max  = .2 Max[e1, e2];
   mag1 = e1/max;
   mag2 = e2/max;
   axes = {Line[{{0,0,0}, {20,0,0}}],
           Line[{{0,-5,0},{0,5,0}}],
           Line[{{0,0,-5}, {0,0,5}}]};
   waveh = Table[Polygon[{{t,0,0}, {t+delta,0,0},
               {t+delta, mag1 Cos[omega (t+delta)+phase1],0},
               {t,mag1 Cos[omega t+phase1],0}}],
               {t, 0, 20-delta, delta}];
   wavev = Table[Polygon[{{t,0,0}, {t+delta,0,0}, 
               {t+delta,0,mag2 Cos[omega (t+delta)+phase2]},
               {t,0,mag2 Cos[omega t+phase2]}}],
               {t, 0, 20-delta, delta}];
   Show[Graphics3D[{axes, wavev, waveh}], 
      PlotRange->{{0,20}, {-5,5}, {-5,5}},
      Axes->True,
      AxesLabel->{"k", "h", "v"},
      Ticks->None]
     ]

Clear[rotatingField];
rotatingField[mag1_, mag2_, phase1_, phase2_]:=
Block[{vector, ellipse}, 
   ellipse = Line[Table[{mag1 Cos[t+phase1],mag2 Cos[t+phase2]},
                        {t,0,2 Pi,Pi/25}]];
   Do[vector = {Thickness[0.01],  PointSize[0.03],
        Line[{{0, 0},
              {mag1 Cos[t+phase1],mag2 Cos[t+phase2]}}],
        Point[{mag1 Cos[t+phase1], mag2 Cos[t+phase2]}],
        Line[{{0, 0},
              {0, mag2 Cos[t+phase2]}}],
        Line[{{0,0}, 
              {mag1 Cos[t+phase1], 0}}], 
        Point[{mag1 Cos[t+phase1], 0}], 
        Point[{0, mag2 Cos[t+phase2]}]};
      Show[Graphics[{vector, ellipse}],
           AxesLabel->{"h,(V/m)", "v,(V/m)"},
           PlotRange -> {{-1.05 mag1, 1.05 mag1}, {-1.05 mag2, 1.05 mag2}},
           AspectRatio -> Automatic,
           Axes->Automatic],
     {t, 0, 2Pi, Pi/15}]
]

rotatingField3D::usage = 
"rotatingField3D[magnitudeX_, magnitudeY_, phaseX_, phaseY_]
a sixty-one-frame animation of Etotal as a function of time."

Clear[rotatingField3D];
rotatingField3D[mag1_, mag2_, phase1_, phase2_] :=
Block[{axes, max, point, pi, time},
   pi = N[Pi];
   max = Max[mag1,mag2];
   delta = pi/15;
   axes = {Line[{{0,0,0}, {20,0,0}}],
           Line[{{0,-5,0}, {0,5,0}}],
           Line[{{0,0,-5}, {0,0,5}}]};
   filler[-1] = { };
   Do[filler[time] = Flatten[{filler[time-1],
         Polygon[{{time delta,0,0},
               {(time+1) delta,0,0},
               {(time+1) delta,
                mag1 Sin[(time+1) delta + phase1], 
                mag2 Sin[(time+1) delta + phase2]},
               {time delta,
                mag1 Sin[time delta + phase1],
                mag2 Sin[time delta + phase2]}}]}];
       point = {PointSize[0.03],
               Point[{(time+1) delta ,
                      mag1 Sin[(time+1) delta + phase1],
                      mag2 Sin[(time+1) delta + phase2]}]};
      Show[Graphics3D[{axes, filler[time], point},
         BoxRatios -> {2,1,1}],
         PlotRange -> {{0, 4 pi},{-max,max},{-max,max}},
         Axes -> True,
         Ticks -> None,
         AxesLabel->{"time", "h", "v"},            
         AspectRatio -> Automatic],
      {time, 0, 60}]
 ]

On[General::spell1]