Physics Lab - Explore Concept with Mathematica Language

You drop your physics textbook from the top of the world's tallest tree and it takes 5 seconds to hit the ground.  How far did it fall?

d=(1/2)a (t^2)

(1/2) (-9.8 Meters/(Second^2)) (((5 Second))^2)

Seeing that the physics textbook wasn't damaged, you decide to go to the roof of a skyscraper building and drop your book again.  This time, it takes 10 seconds to hit the ground, how far did it fall?

Do you expect the distance to be twice as far since the book fell for double the amount of time?

(1/2) (-9.8 Meters/(Second^2)) (((10 Second))^2)

idealdata=
Table[{
i,
0.5 9.8 (i^2)
},
{i, 5, 10, 1}
];
Prepend[idealdata, {"Time", "Distance"}]
fitdata=
Fit[idealdata, {(x^2),x,1}, x]
Show[
ListPlot[
idealdata,
AxesOrigin->{0,0},
AxesLabel->{"Time", "Freefall Distance"} ,
Filling->Axis,
PlotStyle->PointSize[0.02]
],
Plot[fitdata, {x, 0, 10}]
]

Physics Lab - Explore Concept with Mathematica Application

You drop your physics textbook from the top of the world's tallest tree and it takes 5 seconds to hit the ground.  How far did it fall?

d=(1/2)a (t^2)

(1/2) (-9.8 Meters/(Second^2)) (((5 Second))^2)

Seeing that the physics textbook wasn't damaged, you decide to go to the roof of a skyscraper building and drop your book again.  This time, it takes 10 seconds to hit the ground, how far did it fall?

Do you expect the distance to be twice as far since the book fell for double the amount of time?

(1/2) (-9.8 Meters/(Second^2)) (((10 Second))^2)

Use the following application to visualize lots of cases.  Try several time values from 3 seconds to 15 seconds, and record the data corresponding to the particular time on the right side in your virtual lab notebook.

Panel[
DynamicModule[
{datacapture={}, time=0, height=0, currenttime=0, datalist={}, lineardatafit=0, polydatafit=0, polygraph=Plot[0, {x, 0, 20}], lineargraph=Plot[0, {x, 0, 20}], measureddata={}, measuredpath="highlight and replace"},
Row[{(*start of left side*)
Column[{(*start of content on left side*)
Style["Freefall Animation", Medium, Bold],
(*list of equations*)
Row[{Style["distance = (1/2) acceleration (time^2)", Medium],
Style["     accerleration is gravity = - 9.8 m / s", Medium]
}],
" ",
(*start of instructions*)
Style["Step 1.  Enter freefall time and watch animation:", Blue],
(*start of button which defines height value to create animation*)
Row[{
"Free Fall Time in Seconds (choose 3 - 15):",
InputField[Dynamic[time], FieldSize->4],
Button["Create Animation",
height=(9.8*(time^2))/2,
Method->"Queued", ImageSize->120
]
}],
(*start of slider that controls time for specific animation*)
Row[{
"Time Control:  ",
Slider[Dynamic[currenttime], {0, Dynamic[time]}]
}],
(*start of list of calculations that auto-update as Time Control changes*)
Row[{
Style["Elapsed Time:       ", Red],
Dynamic[N[currenttime, 2]],
" sec   "
}],
Row[{
Style["Current Height:    ", Red],
Dynamic[N[height-((9.8*(currenttime^2))/2), 2]],
" meters   "
}],
Row[{
Style["Current Velocity:  ", Red],
Dynamic[-9.8*currenttime],
" m / s"
}],
(*start of animation, rectangles to convey size of building that vary in size depending on height*)
Dynamic[
If[
time===0,
"ready to create animation....",
Graphics[{
(*start of lines that represent building of varying height*)
Table[
Rectangle[{5,i-15}, {5+(height*0.05),i}],
{i, height, 1, -20}
],
(*start of rectangle that represents ground*)
Rectangle[{-(height/2),0.5}, {5+(height*0.05), -(height/10)}],
(*start of point that represents falling object*)
{PointSize[Large], Point[{-(height/30),Dynamic[height-((9.8*(currenttime^2))/2)]}]}},
(*start of options for animation plot including size and perspective*)
PlotRange->{{-(height/2)*1.2, 7+(height*.1)},{-height*.1, height*1.1}},
ImageSize->{350, 350}, Background->White
]
]
]
}],
"       " (*space between left and right sides*),
(*start of right side*)
Column[{(*start of content on right side*)
(*start of instructions*)
Style["Step 2.  Compare Distance Data at Various Times:", Blue],
(*start of button that defines a list of (time, height), appends to list as button is clicked*)
Row[{
"Capture at Several Time Values:  ",
Button["Record Current Total Distance",
AppendTo[datalist, {time, height}]
],
"   ",
(*start of button that clears data*)
Button["Clear Data",
datalist={};
]
}],
Row[{
"Fit Equation to Data:  ",
Button["Linear Fit",
lineardatafit=Fit[datalist, {x, 1}, x];
lineargraph=Plot[lineardatafit, {x, 0, 20}]
],
"   ",
Button["Polynomial Fit",
polydatafit=Fit[datalist, {(x^2),x, 1}, x];
polygraph=Plot[polydatafit, {x, 0, 20}]
],
"   ",
Button["Clear Fitted Equations",
polygraph=Plot[0, {x, 0, 20}];
lineargraph=Plot[0, {x, 0, 20}]
]
}],
(*start of list plot that shows running list of (time, height) defined by button above*)
Dynamic[Which[
datalist==={}&&measureddata==={},
"ready to record data here...",
datalist≠{}&&measureddata==={},
Show[
ListPlot[
datalist,
AxesOrigin->{0,0},
AxesLabel->{"Time", "Freefall Distance"} ,
Filling->Axis,
PlotStyle->PointSize[0.02], Background->White
], 
polygraph,
lineargraph,
ImageSize->400
],
datalist==={}&&measureddata≠{},
Show[
ListPlot[
measureddata,
AxesOrigin->{0,0},
AxesLabel->{"Time", "Freefall Distance"} ,
Filling->Axis,
PlotStyle->PointSize[0.02], Background->White
], 
polygraph,
lineargraph,
ImageSize->400
],
datalist≠{}&&measureddata≠{},
Show[
ListPlot[
{measureddata, datalist},
AxesOrigin->{0,0},
AxesLabel->{"Time", "Freefall Distance"} ,
Filling->Axis,
PlotStyle->PointSize[0.02], Background->White
], 
polygraph,
lineargraph,
ImageSize->400
]
]
],
Style["Step 3.  Import Your Measured Data for Comparison:", Blue],
"File Path for Measured Data:",
Row[{
InputField[Dynamic[measuredpath]],
Button["Import Data",
measureddata=Partition[Flatten[Import[measuredpath]], 2]
]
}],
"percentage close/far from ideal data",
"residuals between ideal fit and your fit"
}]
}]
]
]

Pre-Lab questions:

(1)  What happens to the velocity as the book falls?  Why isn't this constant?

Answer:  __________________________________________________

(2)  Using the application above, does the linear fit or the polynomial fit work better?

Answer:  __________________________________________________

(3)  You estimated above whether double the freefall time means the distance doubles.  Were you right?  Discuss using your caputured data.

Answer:  __________________________________________________

(4)  Using the better equation, if your textbook falls for 50 seconds, how far did it fall?  Estimate whether this higher or lower than the elevation of Mount Everest, then use WolframAlpha.com to answer the question.

Answer:  __________________________________________________