Are you a god? Would you create me new?
   	Transform me, then, and to your power I'll yield.
   	
   	William Shakespeare, The Comedy of Errors, III.2

Laplace Transforms

Steve Dunbar

Department of Mathematics and Statistics
University of Nebraska-Lincoln
Lincoln, NE 68588-0323
sdunbar@mathlab01.unl.edu

Math 221H, Fall 1993

Covers Nagle & Saff, Chapter 7

First, we need to load the definitions of Laplace Transforms for Mathematica

<<Calculus`LaplaceTransform`

Basic Exercises

Laplace Transforms of Elementary Functions

LaplaceTransform[ Sin[t], t,s]

Plot[ LaplaceTransform[ Sin[t], t,s], {s,0,10}]

LaplaceTransform[ t^3 Exp[a t], t, s]

Plot[LaplaceTransform[ t^3 Exp[3 t], t,s], {s, 0, 10},
PlotRange ->{0,100}]

Note the Laplace Transform is defined only for s > 3, just as described in the theory.

LaplaceTransform[ t^Pi, t,s]

Plot[ LaplaceTransform[ t^Pi, t,s], {s, 0,10}]

Make a conjecture about the behavior of a Laplace Transform as the argument s -> Infinity, based on these graphs.

InverseLaplaceTransform[1/(s^2 + 5)^2, s,t]

Simplify[%]

Solving Differential Equations with Laplace Transforms

algeqn =
LaplaceTransform[ y''[t] - 2 y'[t] + 5 y[t] == 1 + t, t,s]

algeqn = algeqn /. {y[0] -> 0, y'[0] -> 4}

algsoln = Solve[ %, LaplaceTransform[ y[t], t,s] ]

Y = LaplaceTransform[ y[t], t,s] /. %

Y = First[Y]

Apart[ Y,s]

InverseLaplaceTransform[%, s,t]

Simplify[%]

Exercise 1

Nagle & Saff, page 309, Section 7.5, #19
Solve 
	y'' + 5 y' - y = exp(t) - 1
	y(0) = 1
	y'(0) = 1

Laplace Transforms of Step and Periodic Functions

What Can Mathematica Do?

Warm-ups

InverseLaplaceTransform[ Exp[-4s]/(s^2 + 4), s,t]

Plot[%, {t,0,10}]

A Diff Eq with a Step Function Right-Hand Side

NDSolve[ {y'[t] + y[t] == If[t <= 4, 1, -1], y[0] == 0},
 y, {t,0,10},
 MaxSteps->1000]

Plot[Evaluate[y[t]/. %], {t,0,10},
PlotRange-> All]

A Diff Eq with a Periodic Right-Hand Side

Plot[Which[t<1, 1, t<2, -1, t<3, 1, t<4, -1, t<=5, 1],
  {t,0,5}]

NDSolve[ {y'[t] + y[t] ==
    Which[t<1, 1, t<2, -1, t<3, 1, t<4, -1, t<=5, 1],
 y[0] == 0},
 y, {t,0,5}]

Plot[ Evaluate[y[t] /. %], {t,0,5}]

What Mathematica Can't Do (Directly)

HeavisideStep[a_,x_] := If[ x>=a, 1,0]

Plot[ HeavisideStep[1,x], {x,0,3}]

LaplaceTransform[HeavisideStep[1,t], t,s]

On the other hand, using the proper Mathematica definitions.....

LaplaceTransform[ UnitStep[t-1], t,s]

SquareWave[x_] := If[EvenQ[Floor[x]], 1, -1]

Plot[ SquareWave[t], {t,0,10}]

LaplaceTransform[ Abs[ Sin[t]], t,s]

Dirac Delta Functions

Plot[ DiracDelta[t-1], {t,-1,1}]

Integrate[ DiracDelta[t-1] Exp[t], {t,0,2}]

LaplaceTransform[ DiracDelta[t-1] Exp[t], t,s]

LaplaceTransform[ DiracDelta[t-1], t,s]

Plot[ %, {s,0,10}]

LaplaceTransform[ DiracDelta[t], t,s]

What does this say your previous conjecture about the limiting behavior of Laplace transforms?