Mathematica High Performance and High Productivity Computing (((HPC))^2) -Mathematica高性能及高效率计算

With[{z=x+I y},Plot3D[Im[(((-4 (z^10)+4 (z^9)+4 (z^8)+6 (z^7)-7 (z^6)+7 (z^5)+5 (z^4)+(z^3)+6 (z^2)+4 z-5))^(1/7))],{x,-(3/2),(3/2)},{y,-(3/2),(3/2)},Mesh->None,MaxRecursion->3,ExclusionsStyle->{None,Red},PlotStyle->Directive[Specularity[White,20],Yellow,Opacity[0.8]]]]

Presenter - 主讲人

Roger Germundsson
Director of Research and Development - 研发部总监
Wolfram Research, Inc
roger@wolfram.com

Overview - 综述

Thousands of improvements some large and some small - 数以千计的改进大型和小型的
[new in 7 summary - 7 的新功能概要] [new in 6 summary - 6的新功能概要]

In this talk I will focus on: - 在这次演讲中，我将重点放在

Documentation and Learning  - 参考文档资料及学习

Visualization and Graphics  - 可视化及图形

Dynamic Interactivity - 动态交互

Data Handling and Data Sources - 数据处理及数据资源

Mathematics and Algorithms - 数学及算法

Parallel Computing  - 并行计算

Documentation and Learning - 参考文档资料及学习

Documentation - 参考文档资料

300+ guide pages or  "concept maps" [root guide page] [sample guide page]
300+ 指南页或"概念图"[指南首页] [指南样本]

4000+ reference pages with some 50,000+ carefully developed examples [sample ref page]
4000+ 参考页, 拥有50,000+ 精心设计的实例[ 参考页样本]

600+ tutorials, including updated sections from the Mathematica book [sample tutorial]
600+ 教程, 其中包括最新的 Mathematica 书籍[教程样本]

a number of how-to task oriented documents [howto] - 一些以"如何"为主题的文档[如何]

150,000+ cross links between document elements - 150,000+ 文档资料间的交叉链接

dynamic updating of in-product documentation elements - 动态更新的产品文档内容

identical on-web and in-product documentation [reference.wolfram.com] - 相同的网络在线和产品文档

in-product and on-web linguistic-aware search system - 产品及网络语言感知搜索系统

Other - 其它

free live seminars [seminar list] - 免费实时在线讲座 [讲座列表]

paid live courses [course list] - 付费实时在线讲座[课程列表]

4500+ online demonstrations [demonstrations] - 4500+ 在线演示[演示]

many more online resources [web resources] - 更多的网络资源 [网络资源]

Visualization and Graphics – Overview  [7.0][6.0] (可视化及图形 - 综述)

new 2D and 3D interactive real-time renders and rich modern graphics languages
新的二维和三维交互式实时渲染和丰富的现代图形语言

new geometry based engine for function and data visualization
新的几何引擎下的函数和数据的可视化

new geometry based engine for vector field visualization
新的几何引擎下的矢量场的可视化

new optimization based layout engine for graph and network visualization
新的优化布局引擎下的图形和网络的可视化

new dynamic charts engine for information visualization
新的动态图表引擎下的信息的可视化

fully integrated with typesetting, interactive controls and documents
完全整合的排版，交互式的控制和文档

2D Graphics - 二维图形

Graphics evaluate to its rendered image: - Graphics 产生的渲染图像

g=Graphics[{Pink,Disk[]}]

Combine with any other expression:  - 结合其它任意表达式

Integrate[(1/(1+(g^3))), g]

New primitives and directives [more...]: - 新的图元及指令 [更多...]

Graphics[Table[{Hue[k/40],Arrow[{{0,0},{Cos[2k Pi/40],Sin[2k Pi /40]}}]},{k,40}]]

Graphics[Table[{Hue[t/15,1,.9,.3],
Disk[{Cos[2Pi t/15],Sin[2Pi t/15]}]},{t,15}]]

Graphics[BSplineCurve[RandomReal[1,{10,2}]]]

3D Graphics - 三维图形

Graphics3D evaluates to its rendered image: - Graphics3D产生的渲染图像

g=Graphics3D[Cone[]]

Combine with other expressions: - 结合其它任意表达式

Expand[(((1+g))^3)]

New primitives and directives [more...]: - 新的图元及指令[更多...]

Graphics3D[Table[{EdgeForm[Gray],Hue[RandomReal[]],Cylinder[RandomReal[10,{2,3}]]},{20}]]

Graphics3D[Tube[BSplineCurve[RandomReal[.1,{20,3}]]]]

Graphics3D[{Arrowheads[{{.1,1}}],Arrow[Tube[{{0,0,0},{0,-1,0}},.025]],Arrow[Tube[{{0,0,0},{0,0,1}},.025]],Arrow[{{.5,0,0},{.5,-1,0}}],Arrow[{{.5,0,0},{.5,0,1}}],Arrowheads[{{.02,1,Graphics3D[Sphere[]]}}],Arrow[{{1,0,0},{1,-1,0}}],Arrow[{{1,0,0},{1,0,1}}],Arrowheads[{{.02,1,Graphics[Disk[]]}}],Arrow[{{1.5,0,0},{1.5,-1,0}}],Arrow[{{1.5,0,0},{1.5,0,1}}]},PlotRange->{{0,1.6},{-1,0},{-.1,1}},Boxed->False]

Graphics3D[With[{c=ColorData["SouthwestColors"]},{Opacity[.7],Specularity[White,20],c[0],Sphere[],Table[{c[i/7],Sphere[{Cos[2 Pi i/6],0,Sin[2Pi i/6]},1]},{i,6}]}],Lighting->"Neutral",Boxed->False,ViewPoint->Front]

Graphics3D[BSplineSurface[Table[{i,j,RandomReal[{-1,1}]},{i,5},{j,5}]]]

Function Visualization – Infinite Data Sets [more...] (函数的可视化 -无限数据集) [更多...]

Adaptive sampling (all functions): - 自适应采样(所有函数)

Plot[Sin[1/x],{x,0,1},Mesh->All]

ParametricPlot3D[{Sin[u],Sin[v],Sin[u+v]},{u,0,2 π},{v,0,2 π},Mesh->All]

Multiple functions: - 多种函数

Plot[Evaluate@Table[BesselJ[n,x],{n,4}],{x,0,10},Filling->Axis]

Plot3D[{Re[Sin[x+I y]],Im[Sin[x+I y]]},{x,-2Pi,2Pi},{y,0,2},BoxRatios->Automatic,Ticks->{Range[-2Pi,2Pi,Pi],{0,1,2}},Mesh->None,PlotStyle->{Yellow,Cyan},AxesLabel->Automatic]

Use exclusions to specify cuts in curves and surfaces: - 使用Exclusions指定曲线和曲面的切割

Plot[Tan[x],{x,0,10}]

Plot[Tan[x],{x,0,10},Exclusions->{Cos[x]==0}]

Plot3D[Tan[x y],{x,0,3},{y,0,3},Exclusions->{Cos[x y]==0},Mesh->None]

Automatically compute exclusions: - 自动计算排除点

Plot[Sin[Floor[2x]],{x,0,10},ExclusionsStyle->Directive[Red,Dashed]]

Plot3D[Im[ArcSin[(((x+I y))^5)]],{x,-2,2},{y,-2,2},Mesh->None,ExclusionsStyle->{None,Red}]

Plot3D[Im[(Sqrt[Cos[y]+I Sin[x]])],{x,-5,5},{y,-5,5},Mesh->None,PlotStyle->Directive[Specularity[White,20],Yellow,Opacity[0.8]]]

Data Visualization – Finite Data Sets [more ...] (数据的可视化 -有限数据集) [更多...]

Support unstructured data (everywhere): - 广泛地支持非结构化数据

data=Table[{x=RandomReal[{-1,1}],y=RandomReal[{-1,1}],x^2-y^2},{1000}];

ListPlot3D[data,BoxRatios->Automatic,Mesh->All]

ListDensityPlot[data,Mesh->All]

ListContourPlot[data,Mesh->All]

Multiple data sets: - 多个数据集

ListPlot[Table[{k,PDF[BinomialDistribution[50,p],k]},{p,{0.3,0.5,0.8}},{k,0,50}],Filling->Axis]

ListLinePlot[Table[{k,PDF[BinomialDistribution[50,p],k]},{p,{0.3,0.5,0.8}},{k,0,50}],Filling->Axis]

ListPlot3D[Table[a Sin[x y],{a,{-1,1}},{x,0,3,0.1},{y,0,3,0.1}],PlotStyle->{Green,Yellow}]

Provide smoothing or interpolation: - 提供平滑或插值

Table[ListLinePlot[{{1,4,2,3,10,8,2}},InterpolationOrder->i,Mesh->Full],{i,0,3}]

data=Table[Sin[j^2+i],{i,0,Pi,Pi/5},{j,0,Pi,Pi/5}];

Table[ListPlot3D[data,Mesh->None,InterpolationOrder->i,ColorFunction->"SouthwestColors"],{i,0,3}]

ListPlot3D[RandomReal[{},{50,3}],InterpolationOrder->0,Filling->Bottom,Mesh->None,ColorFunction->"Rainbow"]

Common Visualization Features - 通用的可视化功能

Automatic region of interest: - 自动绘制感兴趣的区域

Plot[Sec[x],{x,0,10}]

Plot[Sec[x],{x,0,10},PlotRange->All]

Plot3D[Im[Sec[(((x+I y))^3)]],{x,-2,2},{y,-2,2},Mesh->None]

ListLinePlot[Table[Sec[x],{x,0,10,.1}]]

General implicit region clipping: - 常用的隐式区域剪辑

ParametricPlot3D[ {Cos[ ϕ] Sin[θ], Sin[ϕ]Sin[θ], Cos[θ]},{ϕ, 0, 2π}, {θ, 0, π}, RegionFunction -> Function[{x,y,z, ϕ, θ}, Sin[6 ϕ]Sin[6θ]≥ 1/4], PlotPoints -> 25, Mesh->None,BoundaryStyle->Black,PlotStyle->Yellow]

DensityPlot[Sin[x+y^2],{x,-2,2},{y,-2,2},RegionFunction->Function[{x,y,z},0<Mod[x^2+y^2,2]<1],BoundaryStyle->Red]

General overlay meshes: - 常用的网格覆盖

Plot3D[(x^2-y^2)/(x^2+y^2)^2,{x,-1.5,1.5},{y,-1.5,1.5},BoxRatios->Automatic,PlotPoints->25,MeshFunctions->{#3&}]

Plot3D[(x^2-y^2)/(x^2+y^2)^2,{x,-1.5,1.5},{y,-1.5,1.5},BoxRatios->Automatic,PlotPoints->25,MeshFunctions->{#3&},MeshStyle->Purple,MeshShading->{None,Green,None,Yellow}]

Use overlay to display different information: - 利用覆盖，以显示不同的信息

Clear[x,y,z];
$TrigFunctions={Sin,Cos,Sec,Csc,Tan,Cot,ArcSin,ArcCos,ArcSec,ArcCsc,ArcTan,ArcCot};

Table[Plot3D[Abs[f[x+I y]],{x,-2,2},{y,-2,2},MeshFunctions->Function@@@{{{x,y,z},Re[f[x+I y]]},{{x,y,z},Im[f[x+I y]]}},MeshStyle->{Orange,Green},MeshShading->{{None,Yellow},{Orange,None}},PlotLabel->f,Ticks->None],{f,$TrigFunctions}]

General overlay color functions:  - 常用的覆盖着色函数

cd=ColorData["Gradients"]

Table[Plot3D[((x^2)+(y^2)) Exp[-((x^2)+(y^2))],{x,-2,2},{y,-2,2},ColorFunction->g],{g,Take[cd,6]}]

Graph Visualization – Network Data Sets (图形可视化 - 网络数据集)

Automatically draw graphs in 2D and 3D: - 自动绘制二维及三维图形

GraphPlot[Table[i->Mod[i^2,102],{i,0,102}]]

GraphPlot3D[Table[i->Mod[i^2,75],{i,75}],SelfLoopStyle->None,MultiedgeStyle->None,EdgeRenderingFunction->({Cylinder[#1,0.1]}&),VertexRenderingFunction->({Sphere[#,0.3]}&)]

Use specialized layouts for trees: - 使用专门布局的树状结构

TreePlot[{1->7,2->5,3->6,3->7,3->9,4->8,5->8,6->8},VertexRenderingFunction-> (Inset[,#1]&)]

TreeForm[Integrate[1/(1-x^2),x]]

Use a layered layout (useful for DAGs) [more...] - 使用分层布局(适用于DAGs)[更多...]

LayeredGraphPlot[{1->2,1->3,2->3,1->4,2->4,1->5}]

g={"5th Edition"->"6th Edition","5th Edition"->"PWB 1.0","6th Edition"->"1 BSD","6th Edition"->"Interdata","6th Edition"->"LSX","6th Edition"->"Mini Unix","6th Edition"->"Wollongong","PWB 1.0"->"PWB 1.2","PWB 1.0"->"USG 1.0","1 BSD"->"2 BSD","Interdata"->"PWB 2.0","Interdata"->"Unix/TS 3.0","Interdata"->"7th Edition","PWB 1.2"->"PWB 2.0","USG 1.0"->"USG 2.0","USG 1.0"->"CB Unix 1","7th Edition"->"2 BSD","7th Edition"->"32V","7th Edition"->"Xenix","7th Edition"->"Ultrix-11","7th Edition"->"UniPlus+","7th Edition"->"V7M","PWB 2.0"->"Unix/TS 3.0","USG 2.0"->"USG 3.0","CB Unix 1"->"CB Unix 2","32V"->"3 BSD","Unix/TS 1.0"->"Unix/TS 3.0","USG 3.0"->"Unix/TS 3.0","CB Unix 2"->"CB Unix 3","3 BSD"->"4 BSD","V7M"->"Ultrix-11","Unix/TS 3.0"->"TS 4.0","CB Unix 3"->"Unix/TS++","CB Unix 3"->"PDP-11 Sys V","4 BSD"->"4.1 BSD","Unix/TS++"->"TS 4.0","4.1 BSD"->"8th Edition","4.1 BSD"->"4.2 BSD","4.1 BSD"->"2.8 BSD","2 BSD"->"2.8 BSD","TS 4.0"->"System V.0","4.2 BSD"->"4.3 BSD","4.2 BSD"->"Ultrix-32","2.8 BSD"->"2.9 BSD","2.8 BSD"->"Ultrix-11","System V.0"->"System V.2","8th Edition"->"9th Edition","System V.2"->"System V.3"};

LayeredGraphPlot[g,VertexLabeling->True]

LayeredGraphPlot[{->,->,->,->,->,->,->,->,->,->,->,->,->,->,->,->},VertexLabeling->True,DirectedEdges->True]

Charting [more ...] - 制图[更多...]

By default charts are dynamic: - 默认情况下图表是动态的

PieChart[{1,2,3}]

Single, multiple or missing data: - 单个，多个或丢失的数据：

BarChart[{1,2,3}]

BarChart[{{1,2,3},{2,3,4}}]

Use different types of wrappers for styling and labeling: - 使用不同类型的包装样式和标识：

BarChart[{1,Style[2,Red],3}]

BarChart[{1,Labeled[2,"Special"],3}]

obj={Graphics[{Pink,Disk[]},ImageSize->30],BarChart[{1,2,3},Axes->None,ImageSize->30],Graphics3D[Sphere[],ImageSize->30],Checkbox[],(π^E)};

Table[BarChart[{1,Labeled[2,lab,Above],3},Ticks->None],{lab,obj}]

Wrappers for information drill-down: - 深层信息的包装

BarChart[{1,Tooltip[2,"hello"],3}]

BarChart[{1,Button[2,Speak[2]],3}]

BarChart[{1,Button[2,CreateDialog[PieChart[Range[5]]]],3}]

Use different layouts: - 使用不同的布局

Table[BarChart[RandomReal[1,{3,5}],ChartLayout->l,PlotLabel->l,ImageSize->Medium],{l,{"Grouped","Stepped","Stacked","Percentile"}}]

Use different procedural chart elements: - 使用不同的程序图表元件

Table[PieChart[Range[5],ChartElementFunction->f,ChartStyle->47],{f,ChartElementData["PieChart"]}]

Use graphic chart elements: - 使用图形图表元件

BarChart[{1,2,3,4},ChartElements->]

split=First@ImagePartition[,Floor[ImageDimensions[]/{10,1}]]

BarChart[RandomReal[{8,12},10],ChartElements->split,Joined->True,BarSpacing->0]

g=ExampleData[{"Geometry3D","Cow"}]

BarChart3D[Range[5],ChartElements->g,ChartStyle->"Pastel",ImageSize->800]

Other Visualization Functions - 其它可视化函数

Time series data: - 时间序列数据

DateListPlot[FinancialData["GOOG","Jan. 1, 2004"]]

Matrix data: - 阵列数据

ArrayPlot[CellularAutomaton[{1635,{3,1}},{{1},0},80],ColorRules->{0->Black,1->Red,2->Yellow}]

MatrixPlot[Fourier[Table[UnitStep[i,4-i] UnitStep[j,7-j],{i,-50,50},{j,-50,50}]]]

m=ExampleData[{"Matrix","Sandia/fpga_dcop_04"}]

MatrixPlot[m]

GraphPlot3D[m]

ReliefPlot[Import["http://exampledata.wolfram.com/hailey.dem.gz","Data"],ColorFunction->"GreenBrownTerrain"]

Special scales and coordinate systems: - 特殊的度量及坐标系统

LogPlot[Tooltip@{Log[n],n,n Log[n],n^2},{n,10,10^3}]

PolarPlot[(E^(Cos[θ]))-2 Cos[4 θ]+((Sin[(θ/12)])^5),{θ,0,20 π}]

SphericalPlot3D[1+(1/5) Sin[5 ϕ],{θ,0,π},{ϕ,0,2 π},PlotStyle->Directive[Purple,Opacity[0.7],Specularity[White,10]],Mesh->None,PlotPoints->30]

Equations and inequalities: - 方程及不等式

RegionPlot[x^2+y^3<2&&x+y<1,{x,-2,2},{y,-2,2}]

RegionPlot3D[x y z<1,{x,-5,5},{y,-5,5},{z,-5,5},PlotStyle->Directive[Yellow,Opacity[0.5]],Mesh->None]

Table[ContourPlot[Re[f[x+I y]],{x,-Pi,Pi},{y,-Pi,Pi},PlotLabel->f,FrameTicks->{{-Pi,0,Pi},{-Pi,0,Pi}},ClippingStyle->Automatic,ColorFunction->"Pastel"],{f,{ArcSin,ArcCos,ArcCsc,ArcSec,ArcTan,ArcCot}}]

ContourPlot3D[x^2+y^2-(1-z) z^4==0.0,{x,-1,1},{y,-1,1},{z,-1,1},RegionFunction->(#1^2+#2^2<1&),PlotPoints->35,ContourStyle->Directive[Specularity[White,50],Yellow],Mesh->None]

Vector fields [more ...] - 矢量场[更多...]

StreamPlot[{-1-x^2+y,1+x-y^2},{x,-3,3},{y,-3,3}]

Visualizing a function and its gradient field: - 可视化的函数及其梯度场

StreamDensityPlot[Evaluate@{D[Sin[x+(y^2)],{{x,y}}],Sin[x+(y^2)]},{x,-2,2},{y,-2,2},Mesh->5,ColorFunction->"BeachColors",MaxRecursion->1]

Dynamic Interactivity – Overview  [more...] (动态交互 - 综述) [更多...]

create instant interfaces using Manipulate - 使用Manipulate创建即时操作界面

full set of control objects (sliders, buttons, input fields etc) - 一套完整的控制对象（滑块，按钮，输入字段等）

full set of viewers and annotation objects (tab view, slide view, tooltips etc) - 一套完整的视图和注释对象（标签视图，幻灯片视图，工具提示等）

dynamic interactivity language (dynamic and dynamic modules etc) - 动态交互性语言（动态和动态模块等）

support for hardware controllers (gamepads, joysticks, 3d mice etc) - 支持硬件控制器（ 游戏垫，操纵杆，三维鼠标等）

see demonstrations.wolfram.com for many more examples - 更多的例子请参见 demonstrations.wolfram.com

Manipulate Anything - 操纵任意对象

Automatically create an interface for manipulating any expression: - 自动创建一个界面操纵任何表达式

Clear[a,b,x,n]

Manipulate[n!,{n,1,1000,1}]

Manipulate[Expand[(a+b)^n],{n,1,100,1}]

Manipulate[ContourPlot3D[x^2+y^2+a z^3==1,{x,-2,2},{y,-2,2},{z,-2,2},Mesh->None],{a,-2,2}]

Manipulate any number of variables with discrete or continuous domains: - 操纵任意数目的离散或连续域的变量

Manipulate[Plot[Sin[a x+b],{x,0,6}],{{a,2,"Frequency"},1,4},{{b,0,"Phase"},0,10}]

Manipulate[Plot[f[x-x0],{x,0,2Pi}],{f,{Sin,Cos,Tan,Cot}},{x0,0,2Pi}]

Specify custom controls: - 指定自定义的控制

Manipulate[Graphics[Line[{{0,0},p}],PlotRange->2],{{p,{1,1}},Locator}]

A=(({{-1.1, 0.9}, {-1.4, 0.3}}));

Manipulate[ParametricPlot[Evaluate[MatrixExp[A t,#]&/@pt],{t,0,10},PlotRange->5],{{pt,{{2,0},{0,1},{-3,0}}},Locator,LocatorAutoCreate->True},SaveDefinitions->True
]

Dynamic and Control Objects - 动态和控制对象

Dynamic variables maintain dependencies and update ... um dynamically: -动态变量保持相依和更新...嗯动态

e=1;

e

e=2;

e

Dynamic[e]

e=3

e=Integrate[(1/(1-(x^3))),x]

e=Plot[Sin[x],{x,0,2Pi}]

e=.

Controls repeatedly set (or control) variables: - 重复控制集（或控制）变量

Slider[.5]

Slider[Dynamic[e]]

e=.5

{Slider[Dynamic[e]],Dynamic[e]}

You can localize this dependence by introducing dynamic module: - 通过引入动态模块，您可以局部化这种依赖

DynamicModule[{e},{Slider[Dynamic[e]],Dynamic[e]}]

DynamicModule[{e},{Slider[Dynamic[e],{1,10}],Dynamic[Plot[Sin[e x],{x,0,2Pi}]]}]

Apart from this sliders, checkboxes etc are just like any other expression: - 除了滑块，复选框等，就像任何其他的表达式

Expand[(((1+Slider[Dynamic[e]]))^3)]

Also just about anything can be made dynamic: - 而且任何问题都可以用动态

{Slider[Dynamic[n],{5,200}],Style["Wolfram",FontSize->Dynamic[n]]}

This looks slightly long, but compare to other ways of doing it [web]: - 这看起来稍微长，但比较其他方式不算长[网页]

makeHand[fl_, bl_, fw_, bw_]:=Polygon[{{-bw, -bl},{bw, -bl},{fw,fl},{0, fl + 8 fw},{-fw,fl}}/9];
hourHand =makeHand[5, 5/3, .1, .3];
minuteHand =makeHand[7, 7/3, .1, .3];
secondHand = {Red,EdgeForm[Black],makeHand[7, 7/3, .1/2, .3/2]};
Graphics[{
{Thickness[.03],Circle[]},
{Thickness[.003],Table[Line[{.9{Cos[a],Sin[a]},.95{Cos[a],Sin[a]}}],{a, 0, 2π, 2 π/60}]},
{Thickness[.01],Table[Line[{.9{Cos[a],Sin[a]},.95{Cos[a],Sin[a]}}],{a, 0, 2π, 2 π/12}]},
Style[Table[Text[i,.77{Cos[-i π/6 + π/2],Sin[-i π/6+π/2]}],{i, 1, 12}], FontFamily->"Helvetica",FontSize->24],
Rotate[hourHand,Dynamic[Refresh[-6 Mod[AbsoluteTime[]/360,60]°,UpdateInterval->60]],{0,0}],
Rotate[minuteHand, Dynamic[Refresh[-6 Mod[AbsoluteTime[]/60,60]°,UpdateInterval->1]], {0,0}],
Rotate[secondHand, Dynamic[Refresh[-6 Round[Mod[AbsoluteTime[],60]]°,UpdateInterval->.25]], {0,0}]
},ImageSize->Small]

Viewing and Annotation - 视图和注释

Use different viewers to package information compactly: - 使用不同的视图严密地组合信息

TabView[Table[Plot[BesselJ[n,x],{x,0,10}],{n,5}]]

TabView[Table[TraditionalForm@BesselJ[n,x]->Plot[BesselJ[n,x],{x,0,10}],{n,5}]]

SlideView[Table[Plot[BesselJ[n,x],{x,0,10}],{n,5}]]

Use mouseover etc to provide alternate information: - 使用鼠标悬停等提供替代信息

Mouseover[a,b]

data=RandomReal[1,{100,2}];

Mouseover[
ListPlot[data],
ListLinePlot[data[[Last@FindShortestTour[data]]],Mesh->All]
]

Use tooltip to provide additional information: - 使用工具提示，以提供更多的信息

Tooltip[a,b]

Grid@Table[Tooltip[ParametricPlot[{Sin[n t],Sin[m t]},{t,0,2Pi},ImageSize->70,Frame->True,FrameTicks->None,Axes->False],{Sin[n t],Sin[m t]}],{m,3},{n,3}]

Use monitor to temporarily provide a view of information: - 使用监控器，暂时提供信息视图

Monitor[Do[i,{i,10^6}],i]

Monitor[NDSolve[{(∂_(t,t))u[t,x]==(∂_(x,x))u[t,x]+Sin[u[t,x]] ,u[0,x]==(E^(-(x^2))),Derivative[1,0][u][0,x]==0,u[t,-10]==u[t,10]},u,{t,0,10},{x,-10,10},StepMonitor:>(sol=u[t,x]; time=t)],Plot[sol,{x,-10,10},PlotRange->{0,8},PlotLabel->time]]

Data Handling and Data Sources – Overview [more...] （数据处理及数据来源 - 综述） [更多...]

new Import/Export framework that support addressing of elements or parts of files
新的导入/导出框架，支持文件的独立元素或部分文件

large number of new formats and area of coverage (2D/3D graphics, sound, medical, chemical etc) [more...]
大量的新格式和覆盖面（ 2D/3D图形，声音，医学，化学等）[更多...]

full documentation for each supported format (history, elements, examples etc) [sample format]
每个支持格式的完整文档（历史，内容，实例等）[格式样本]

convenience features: URLs, compression, archives etc
便利的特点：网址，压缩，档案等

direct support for computable data (mathematical, physical, chemical, financial etc) [more...]
直接支持可计算的数据（数学，物理，化学，金融等） [更多...]

support for properties to extract potentially smaller part of much larger data sources
支持潜在地提取较大数据资源的一小部分属性

dynamically updated data sources 
动态更新数据来源

Import and Export of Files [more...] - 文件的导入导出 [更多...]

Use the "Elements" to decide what part to import: [file] - 使用 "Elements" ，以决定导入哪些部分[文件]

Import["http://exampledata.wolfram.com/mersenne.xhtml","Elements"]

Import["http://exampledata.wolfram.com/mersenne.xhtml","Data"]

ListLogPlot[%,Joined->True]

Can also import from URLs: - 还可以从网址导入

Import["http://www.eia.doe.gov/pub/international/iealf/table12.xls","Elements"]

Import row 250 from sheet 1: - 从表1导入250行

data=Import["http://www.eia.doe.gov/pub/international/iealf/table12.xls",{"Data", 1,250}]

DateListPlot[Take[data,{4,-1}],{1980},Filling->Bottom,Joined->True]

Use options to control other aspects of the process: -  使用选项来控制处理的其它方面

{Import["ExampleData/aspirin.mol"],
Import["ExampleData/aspirin.mol", "Rendering" -> "Wireframe"],
Import["ExampleData/aspirin.mol", "Rendering" -> "Spacefilling"]}

Computable Data [more...] - 可计算数据[更多...]

Current and historical financial data: - 当前和历史财经数据

DateListPlot[FinancialData["GOOG",{2004}],Joined->True]

Current and historical weather data: - 当前和历史气象数据

WeatherData["SanFrancisco","Temperature"]

DateListPlot[WeatherData["SanFrancisco", "MeanTemperature", {{2004, 1, 1}, Date[], "Day"}], Joined->True]

Combine with country data to display weather stations: - 结合国家数据来显示气象站

Show[
Graphics[{Gray,CountryData["World","Polygon"]}],
Graphics[{Red,Point@Table[Reverse@WeatherData[s,"Coordinates"],{s,WeatherData[]}]}]
]

Use geodesy functions to show locations within 500km of Budapest: - 利用大地测量函数，显示布达佩斯500公里内的地点

Show[
Graphics[{EdgeForm[Black],LightGray,CountryData["Europe","Polygon"]}],ParametricPlot[Reverse@GeoDestination[GeoPosition[CityData["Budapest","Coordinates"]],{500000,t}][[1]],{t,0,360},PlotStyle->Directive[Red,Thick]]
]

The adjacency graph for countries in South America: - 南美洲国家的邻接图

GraphPlot[Flatten[Thread[#->CountryData[#,"BorderingCountries"]]&/@CountryData["SouthAmerica"]],VertexLabeling->True,MultiedgeStyle->None]

Color countries by the length of their claimed indepence: - 根据它们声称独立日的时间长度， 来着色国家

Take[SortBy[CountryData[],CountryData[#,"IndependenceYear"]&],20]

Graphics[{Hue[2/3 Sqrt[1-(CountryData[#,"IndependenceYear"]/. _Missing->2007)/2007]],CountryData[#,"SchematicPolygon"]}&/@CountryData[]]

Create various interactive ways to view data: - 创造各种互动方式查看数据

TabView[Show[CountryData[#,"Shape"],ImageSize->40]->DateListPlot[CountryData[#,{{"GDP"},{1970,2008}}]]&/@CountryData["G8"]]

Image Processing [more...] - 图像处理[更多...]

Use images directly as input (e.g. just copy and paste): - 直接使用图片作为输入（例如，只要复制并粘贴）

i=

Or import from a file or URL: - 或从文件或网址导入

i=Import["http://www.chinapictures.org/images/china-panda-bear/1/china-panda-bear-50622091709021.jpg"]

Apply any function: - 适用任何函数

ImageApply[Abs@Sin[#  2π]&,i]

Or any filter: - 或任何滤波器

Table[Labeled[filter[,2],filter],{filter,{Blur,Sharpen,MeanFilter,GaussianFilter,MedianFilter,MinFilter,CommonestFilter}}]

Or morphological operations: - 或形态操作

Manipulate[Dilation[,r],{r,1,5,1}]

ArrayPlot[MorphologicalComponents[],ColorFunction->"Rainbow"]

Or effects: - 或效果

i=Image@ContourPlot3D[x^4+y^4+z^4-(x^2+y^2+z^2)^2+3(x^2+y^2+z^2)==3,{x, -2,2}, {y, -2, 2}, {z, -2, 2},Mesh->None,ContourStyle->Directive[Orange,Opacity[0.8],Specularity[White,30]],Axes->None,Boxed->False]

Table[ImageEffect[i, effect],{effect,{"Charcoal","Embossing",{"OilPainting",5},"Solarization"}}]

Mathematics and Algorithms – Overview  [7.0][6.0] （数学及算法 - 综述）

new and improved statistics functionality (descriptive, distributions, regression, ...)
新的和改进的统计函数（描述，分布，回归， ... ）

new and improved numerics solvers (constrained optimization, integration, delay equations, ...)
新的和改进的数值解（约束优化，积分，时滞微分方程， ... ）

new and improved symbolics solvers (discrete calculus, continuous calculus, equations, inequalities, ...)	
新的和改进的符号解（离散微积分，连续微积分，方程，不等式， ... ）

new and improved discrete computation (Boolean computation, number theory, graph theory, ...)
新的和改进的离散计算（布尔计算，数论，图论， ... ）

many new special functions 50+
50+ 新的特殊函数

Statistical Computing [more...] - 统计计算[更多...]

Descriptive statistics [more...] - 描述统计学[更多...]

data=RandomReal[NormalDistribution[1,1/2],10^4];

{Mean[data],Variance[data],Skewness[data],Kurtosis[data]}

Histogram[data]

Statistical distributions [more...] - 统计分布[更多...]

Names["*Distribution"]

Symbolic properties of continuous and discrete distributions: - 连续和离散分布的符号属性

dist=NormalDistribution[μ,σ];

{Mean[dist],Variance[dist],Skewness[dist],Kurtosis[dist]}

{PDF[dist,x],CDF[dist,x],InverseCDF[dist,q]}

ExpectedValue[x^10,dist,x]

Clear[n,p,k]

dist=BinomialDistribution[n,p];

{Mean[dist],Variance[dist],Skewness[dist],Kurtosis[dist]}

{PDF[dist,x],CDF[dist,x],InverseCDF[dist,q]}

ExpectedValue[k^3,BinomialDistribution[n,p],k]

DiscretePlot[PDF[BinomialDistribution[50,0.3],k],{k,0,50}]

Fast and high-quality random number generation: - 快速和高质量的随机数生成

RandomReal[1,{10^6,5}];//Timing

RandomInteger[10,{10^6,5}];//Timing

Generate random numbers for any distribution: (10x speedup typically) - 生成任何分布的随机数（ 通常加速10倍）

RandomReal[RayleighDistribution[3],10^6];//Timing

RandomInteger[BernoulliDistribution[3/10],10^6];//Timing

Generate a random choices: - 产生一个随机选择

Clear[a,b,c,d];

RandomChoice[{a,b,c,d},3]

Composition@@RandomChoice[{Sin,Cos,ArcSin,ArcCos,Function[x,1/(1+x^2)],#^3&},3]

StringJoin@@RandomChoice[{"A","C","G","T"},50]

Model fitting using NIST data [more...] -  使用NIST 数据, 拟合模型[更多...]

data= Sort[Import["FilipData.txt","Table"]];
ListPlot[data]

Use the fitted model as a function: - 使用拟合模型作为一个函数

lfit1=LinearModelFit[data,{x,x^2,x^3},x]

Show[ListPlot[data],Plot[lfit1[x],{x,Min[data[[All,1]]],Max[data[[All,1]]]}]]

lfit2=LinearModelFit[data,x^Range[8],x]

Show[ListPlot[data],Plot[lfit2[x],{x,Min[data[[All,1]]],Max[data[[All,1]]]}]]

Use fitted model to get diagnostics: - 使用拟合模型得到结论

lfit1["BestFit"]

lfit1["Properties"]

lfit1["ANOVATable"]

Binning data ... - 组合数据...

BinCounts[{1,3,2,1,4,5,6,2},{0,10,1}]

ListPlot[BinCounts[RandomInteger[BinomialDistribution[50,0.3],10^5],{0,50,1}]/10^4, Filling->Axis]

Clustering data ... - 聚类数据

data={{-1.1,2.6},{3.9,-0.8},{4.2,-3.7},{3.3,3.5},{3.9,5.2},{4.1,-4.8},{3.8,3.7},{5.6,0.1},{3.1,-5.2},{-0.9,2.3},{2.9,4.1},{-2.3,3.9},{-2.5,3.},{2.6,-5.5},{5.2,1.9},{-0.7,1.3},{0.9,2.8},{-1.5,3.3},{3.8,1.2},{2.6,-5.1},{-0.8,3.2},{4.7,0.7},{3.,3.},{3.9,3.6},{4.5,1.4},{4.2,1.3},{-1.1,2.6},{4.8,2.4},{3.3,-3.5},{3.2,-4.6},{3.3,-4.9},{3.,3.5},{0.7,2.1},{3.2,-4.3},{-2.,0.5},{-1.2,2.},{-1.6,1.8},{-3.5,3.7},{4.8,0.2},{3.3,2.4},{-0.1,2.1},{-1.3,2.5},{4.4,3.9},{3.5,0.2},{0.1,2.9},{-1.,1.6},{-1.4,4.5},{3.2,2.5},{-1.6,2.4},{2.6,-5.1}};

ListPlot[FindClusters[data],PlotStyle->PointSize[Large]]

Can use different dissimilarity and distance functions to control clustering: - 可以使用不同的差异和距离函数控制集群

Names["*Dissimilarity"]

Names["*Distance"]

Spatial searching or proximity data ... - 空间搜索或相近的数据...

Nearest[{1,2,3,4,5},3.4]

Nearest[{1,2,3,4,5},3.5]

f=Nearest[{1,2,3,4,5}]

Plot[f[x],{x,0,5}]

data=Table[RandomReal[{-4,4},{2}]->i,{i,40}];

nf=Nearest[data,DistanceFunction->(Norm[#1-#2,Infinity]&)];

ContourPlot[First[nf[{x,y}]],{x,-5,5},{y,-5,5},PlotPoints->35,ColorFunction->"Pastel",Epilog->{Red,PointSize[Large],Point[First/@data]}]

Numeric Computing - 数值计算

Support for constrained optimization using interior point method: (Markowitz porfolio optimization example) 
利用内点法支持约束优化 （马尔克维茨投资組合优化例子）

R=Transpose@{{18.24,12.12,15.23,5.26,2.62,10.42},{12.24,19.16,35.07,23.46,-10.62,-7.43},{8.23,8.96,8.35,9.16,8.05,7.29},{8.12,8.26,8.34,9.01,9.11,8.95}};

ListLinePlot[Transpose@R,PlotRange->All]

{μ,Σ}={Mean[R],Covariance[R]};

X=Table[Subscript[x,i],{i,{"BlueChipStock","TechStock","RealEstate","Bonds"}}];

Find the minimum risk portfolio that returns at least 10%: - 寻找最低风险的投资组合，回报率至少10%

FindMinimum[{X.Σ.X,Total[X]==1&&μ.X≥1.10&&And@@Table[X[[i]]>=0,{i,Length[X]}]},X]

New framework for numeric integration: (oscillatory integrals) - 新框架的数值积分(振荡积分）

Plot[Sin[10^6x]Exp[-x],{x,0,10},PlotRange->All,PlotPoints->200]

NIntegrate[Sin[10^6x]Exp[-x],{x,0,10}]

Combinations (finite oscillatory, infinite oscillatory, singular, piecewise): - 组合（有限振荡，无限振荡，奇异，分段）

f=Piecewise[{{Sin[10 x]/Sqrt[-x],-Infinity<x<0},{1/Sqrt[x],0<x<1},{Sin[2000x]x^2,1<x<2},{Cos[2*x]/x,2<x<Infinity}},0]

Plot[f,{x,-10,10}]

NIntegrate[f,{x,-Infinity,Infinity}]

A 1000 dimensional example: - 一个1000维的例子

Clear[x]

X=Array[x,{10^3}];

NIntegrate[Evaluate[1/(1+Norm[X])],Evaluate[Sequence@@Map[{#,-1,1}&,X]],Method->"AdaptiveQuasiMonteCarlo"]//Timing

Visualize the sampling used in different types of algorithms: - 可视化采样用于不同类型的算法

Table[Graphics3D[{Opacity[0.3],Line[Block[{t=0},Reap[Quiet@NIntegrate[Sqrt[x]+Sqrt[y],{x,0,1},{y,0,1-x^2},EvaluationMonitor:>Sow[{x,y,t++}],Method->m]][[2,1]]]]},BoxRatios->1,PlotLabel->m],{m,{"GlobalAdaptive","LocalAdaptive","QuasiMonteCarlo","AdaptiveQuasiMonteCarlo"}}]

Solve differential-delay equations, compares y'(t)=a y(t) (1-y(t-1)) to y'(t)=a y(t) (1-y(t)):
解决微分时滞方程，比较 y'(t)=a y(t) (1-y(t-1))  和   y'(t)=a y(t) (1-y(t))

Manipulate[
Module[{T = 50, sol, sold},
sol = First[y /. NDSolve[{y'[t] == a y[t](1 - y[t]), y[0]== 0.1}, y,{t,0,T}]];sold = First[y /. NDSolve[{y'[t] == a y[t](1 - y[t - 1]), y[t /; t ≤ 0] == 0.1},y,{t,0,T}]];
 ParametricPlot[{{sol[t],sol[t - 1]},{sold[t],sold[t - 1]}},{t,1,T}, PlotRange->{{0,3},{0,3}}, PlotStyle->{Gray, Blue}]],{{a,1},0, 2}]

Symbolic Computing - 符号计算

Discrete calculus framework [more...] - 离散微积分框架[更多...]

Clear[f,k];

Indefinite sum and difference are inverses: - 不定求和与差分互逆

s=(∑_k)k

(Subscript[∆, k])s

Indefinite product and ratio are inverses: - 不定求积与比率互逆

p=(∏_k)k

(Subscript[\[DiscreteRatio], k])p

Compute the probability for an event: - 计算事件的概率

Sum[Boole[x+y<10] PDF[PoissonDistribution[(Subscript[λ, 1])],x] PDF[PoissonDistribution[(Subscript[λ, 2])],y],{x,0,∞},{y,0,∞},Assumptions->(Subscript[λ, 1])>0&&(Subscript[λ, 2])>0]

Solve new types of functional equations: - 求解新类型的函数方程

RSolve[a[n]==(Sqrt[n])a[(Sqrt[n])]+n,a,n]

RSolve[{M[n]==3 M[(n/2)],M[1]==1},M[n],n]

KaratsubaGasket[n_]:=ksg[n][{0.,0.},{1.,1.}];
ksg[0][c1_,c2_]:=Polygon[{c1,{c1[[1]],c2[[2]]},c2,{c2[[1]],c1[[2]]}}];
ksg[n_][c1_,c2_]:=With[{mid=0.5 (c1+c2)},{ksg[n-1][c1,mid],ksg[n-1][{c1[[1]],c2[[2]]},mid],ksg[n-1][{c2[[1]],c1[[2]]},mid]}];
Manipulate[Graphics[{Orange,KaratsubaGasket[j]}],{j,0,7,1}]

Recognize sequences in different function spaces: - 在不同的函数空间确认序列

Table[Det[HilbertMatrix[n]],{n,10}]

f=FindSequenceFunction[%,n]

Table[Det[HilbertMatrix[n]],{n,10,50}]-Table[f,{n,10,50}]

Many new special functions [6.0] [7.0] - 许多新的特殊函数

With[{b=0.97},Plot3D[Re[QPolyGamma[1,x+I y]],{x,-b,b},{y,-b,b},MaxRecursion->1,RegionFunction->(#1^2+#2^2<b^2&),Mesh->None,PlotStyle->Directive[Yellow,Specularity[White,30]],PlotPoints->35,Exclusions->{{y==0,x≤0}},ExclusionsStyle->{None,Red}]]

Many new simplifiers for special functions (pFq expansion below used to generate 200,000 new identities): 
特殊函数的许多新的简化（ 使用如下pFq扩展来生成200000个新的恒等式 ）

HypergeometricPFQ[{},{3/2,3/2,3/2},((z^4)/64)]//FunctionExpand

HypergeometricPFQ[{a,a+1/2,3},{2a+3,2},z]//FunctionExpand

Improved differential equation solving, in this a solitary wave solution: - 在这个孤波解中，改进微分方程求解

DSolve[Derivative[0,1][y][x1,x2]+6 y[x1,x2] Derivative[1,0][y][x1,x2]+Derivative[3,0][y][x1,x2]==0,y,{x1,x2}]

With[{f=(y[x1,x2]/.First[%])/.{C[1]->1,C[2]->2,C[3]->3}},Plot3D[f,{x1,-4,4},{x2,-4,4},PlotRange->All,Mesh->None,MaxRecursion->5]]

Ability to solve large classes of transcendental equations exactly: - 可以精确求解大量超越方程

Reduce[(127^x)-(113^x)==1,x,Reals]

N[Last[%],100]

Some special roots have symbolic representation, like the zeros of the Zeta function: - 一些根有符号表征，如Zeta函数中的零

Plot[Im[Zeta[1/2+I t]],{t,0,80},Epilog->{PointSize[Medium],Red,Point[Table[{Im[ZetaZero[n]],0},{n,25}]]}]

Equational theorem proving: - 等式定理证明

FullSimplify[f[f[b,a],a]==f[a,f[b,a]],ForAll[{a,b},f[a,b]==f[b,a]]]

FullSimplify[ForAll[x,Exists[y,g[x,y]==e]],ForAll[{x,y,z},g[x,g[y,z]]==g[g[x,y],z]&&g[e,x]==x&&g[inv[x],x]==e]]

Parallel Computing - 并行计算

Some operations are parallel by default, e.g. linear algebra: - 在默认情况下，有些运算是并行的，例如线性代数

A=RandomReal[1,{5000,5000}];

A.A;//Timing

Automatically configured and automatic parallelization [more...] - 自动配置和自动并行 [更多...]

Table[$ProcessID,{5}]

Parallelize[Table[$ProcessID,{5}]]

ParallelTable[$ProcessID,{5}]

Searching for perfect integers: - 寻找完全整数

PerfectQ[n_Integer]:=Total[Divisors[n]]==2n

Select[Range[1000],PerfectQ]

Run a scalar search of the first (10^5) integers: - 运行标搜索第一个(10^5) 整数

Select[Range[(10^5)],PerfectQ]//AbsoluteTiming

DistributeDefinitions[PerfectQ]

Parallelize[Select[Range[(10^5)],PerfectQ],Method-> "EvaluationsPerKernel"-> 2]//AbsoluteTiming

For more control can use concurrency layer: - 使用并发层进行更多的控制

Table[ParallelSubmit[{i},FactorInteger[2^i+1]],{i,200,205}]

WaitAll[%]

Simple Monte Carlo Integration - 简单蒙特卡洛积分

Keywords: Monte Carlo, i.e. random sampling and averaging problem.
关键词： Monte Carlo ，诸如：随机抽样，平均问题

Calculate π by sampling pionts uniformly in a square: - 	在一个正方形中均匀取样来计算π

Solve[((pi (r^2))/((2r)×(2r)))==(PointsInside/TotalPoints),pi]

Use this idea to get an approximate value: - 使用这种方法来获得近似值

pts=RandomReal[{-1,1},{50000,2}];

ipts=Select[pts, Total[#^2]≤1&];

((4. Length[ipts])/(Length[pts]))

Graphics[{Red,Point[ipts],Blue,Point[Complement[pts,ipts]]}]

Package this idea up: - 把这种方法变成程序包

GetPointCounts[n_]:=
{Count[Map[Total[#^2]-1&,RandomReal[{-1,1},{n,2}]],_?Negative],n}

GetPointCounts[10^4]

4. %[[1]]/%[[2]]

Split the problem and have each processor use (10^7) points: - 分解这个问题， 每个处理器使用(10^7)个点

DistributeDefinitions[GetPointCounts]

cts=ParallelMap[GetPointCounts,Table[10^7,{$ProcessorCount}]]

Combine the result: - 组合结果

Map[Total,Transpose[cts]]

4. %[[1]]/%[[2]]

FilledJuliaPlot

A scalar version of FilledJuliaPlot: - FilledJuliaPlot 的标量版本

Options[FilledJuliaPlot]=Sort[Join[Options[Graphics],{PlotPoints->400,MaxIterations->10,Compiled->True}]];

FilledJuliaPlot[f_,{z_,zmin_,zmax_},o:OptionsPattern[]]:=
Catch@Module[{pp,mi,umin,umax,nu,vmin,vmax,nv,F, S},
(* Options *)
pp=OptionValue[PlotPoints]; 
If[IntegerQ[pp],{nu,nv}={pp,pp},{nu,nv}=pp];
mi=OptionValue[MaxIterations];
If[OptionValue[Compiled],F=Compile@@{{{z,_Complex}},f},F=Function@@{z,f}];
{{umin,umax},{vmin,vmax}}=N@{Re@{zmin,zmax},Im@{zmin,zmax}};

(* Computation *)
S=Table[NestWhile[F,u+I v,Abs[#]<2&,1,mi],{v,vmin,vmax,(vmax-vmin)/(nv+1)},{u,umin,umax,(umax-umin)/(nu+1)}];

(* Visualization*)
ReliefPlot[Log[Abs[S]],DataRange->{{umin,umax},{vmin,vmax}},FilterRules[{o},Options[Graphics]],FrameTicks->Automatic,PlotLabel->f]
];

A parallel version, change Table for ParallelTable: - 并行版本， 把Table变成ParallelTable

Options[ParallelFilledJuliaPlot]=Sort[Join[Options[Graphics],{PlotPoints:>ControlActive[100,400],MaxIterations->10,Compiled->True}]];

ParallelFilledJuliaPlot[f_,{z_,zmin_,zmax_},o:OptionsPattern[]]:=
Catch@Module[{pp,mi,umin,umax,nu,vmin,vmax,nv,F, S},
(* Options *)
pp=OptionValue[PlotPoints]; 
If[IntegerQ[pp],{nu,nv}={pp,pp},{nu,nv}=pp];
mi=OptionValue[MaxIterations];
If[OptionValue[Compiled],F=Compile@@{{{z,_Complex}},f},F=Function@@{z,f}];
{{umin,umax},{vmin,vmax}}=N@{Re@{zmin,zmax},Im@{zmin,zmax}};

(* Computation *)
DistributeDefinitions[{F,umin,umax,nu,vmin,vmax,nv,mi}];
S=ParallelTable[NestWhile[F,u+I v,Abs[#]<2&,1,mi],{v,vmin,vmax,(vmax-vmin)/(nv+1)},{u,umin,umax,(umax-umin)/(nu+1)}];

(* Visualization *)
ReliefPlot[Log[0.1+Abs[S]],DataRange->{{umin,umax},{vmin,vmax}},FilterRules[{o},Options[Graphics]],FrameTicks->Automatic,PlotLabel->f]
];

Try it out ...  - 试试看...

Manipulate[ParallelFilledJuliaPlot[(z^2)+l[[1]]+I l[[2]],{z,-2-2I,2+2I},ImageSize->500,PlotPoints:>ControlActive[100,500]],{{l,{0,1}},{-2,-2},{2,2},Locator}]

This quickly becomes addictive ... - 您很快就会迷上它...

ParallelFilledJuliaPlot[(z^6)+I,{z,-2-2I,2+2I},PlotPoints->500,ImageSize->500]

ParallelFilledJuliaPlot[Sin[z^2+I],{z,-2-2I,2+2I},PlotPoints->500,ImageSize->500]

gridMathematica [more...]

Scaling up your parallel Mathematica installation ... the same code scaled to a larger grid. 
扩大您的Mathematica并行安装...相同的代码扩展到更大的网格

gridMathematica Local = Mathematica + 4 subkernels 
gridMathematica 本地 = Mathematica + 4 子核

… the ultimate for an 8-core machine - 最终是8核机器

gridMathematica Server = Mathematica + 16 x subkernels
gridMathematica 服务器 = Mathematica + 16 x 子核

... the perfect department cluster - 完美部集群

... also works with existing batch schedulers (Windows CCS, Windows HPC, Platform LSF, Altair PBS Pro, Sun GridEngine, ...)
...还可以与现有的批处理调度程序一起工作 (Windows CCS, Windows HPC, Platform LSF, Altair PBS Pro, Sun GridEngine, ...)

Lightweight Grid Manager = Mathematica + Adhoc Clusters
Lightweight Grid 管理器 = Mathematica + Adhoc  集群

... reuse idle resources such as computer labs, idle desktops and laptops - 再利用闲置资源，如计算机实验室，闲置的台式机和笔记本电脑

gridMathematica Cloud = Mathematica + Cloud Supercomputers
gridMathematica 云 = Mathematica + 云超级计算

... future product for sending parallel Mathematica jobs to cloud HPC clusters - 未来的产品通过并行Mathematica作业到HPC云集群

Summary - 总结

Initialization - 初始化

$HistoryLength=5;

SetDirectory[FileNameJoin[{NotebookDirectory[],"Data"}]];