Experimental Mathematics: Mathematica's Role in Obtaining New Results on Projectile Motion

Ed Packel

Mathematics Department, Lake Forest College

Overview

A Happy Mathematica "Accident" in Studying Projectile Motion with Resistance

The Lambert W Function--alias ProductLog

A New Closed-Form Formula for the Range Function

A New General Theorem (Thanks, Mathematica!)

The Maximizing Range Angle--Lambert W Returns

Experimental Mathematics--An Ancient Idea is Reborn

Thanks To:

• Charles Groetsch

• Anne Serdynksi and Mihdi Vahedi

• Niccolo Tartaglia, Galileo Galilei, and David Yuen

Niccolo Fontana Tartaglia (1499-1557)

 Galileo Galilei (1564-1642)

 David S. Yuen  (19xx-21xx)

The Problem and its "No-Resistance" Solution

x''=0       x[0]=0,    x'[0]=v*cos θ
y''=-g	      y[0]=0,    y'[0]=v*sin θ

Solve the DE System and Plot the Solution

Clear[x,y];
soln=DSolve[{x''[t]==0,y''[t]==-g,
x[0]==0,y[0]==0,x'[0]==v Cos[θ],y'[0]==v Sin[θ]},{x[t],y[t]},t]

param={x[t_],y[t_]}={x[t],y[t]}/.soln[[1]];
Manipulate[ParametricPlot[param/.{g->32.2,v->50,θ->LaunchAngle},{t,0,((2 v Sin[θ])/g)/.{g->32.2,v->50,θ->LaunchAngle}},AxesLabel->{x,y},PlotRange->{{0,80},{-10,40}},AspectRatio->Automatic,PlotStyle->Thick,ImageSize->Large],{{LaunchAngle,π/3},0.01,π/2,Appearance->"Labeled"}]

Find The Projectile Range: Evaluate x[t] when y[t]=0

y[t]
tvals=Solve[y[t]==0,t]  (* The Impact Time *)
x[t]/.tvals[[2]]   (* The Range *)

Simplify[%]

Plot[(((v^2) Sin[2 θ])/g)/.{v->50,g->32.2},{θ,0,(π/2)},AxesLabel->{Style[θ,20],Style["R in feet",20]},Ticks->{Range[0,(π/2),(π/12)],Automatic},TicksStyle->Directive[Green,Bold,18],ImageSize->Large,PlotLabel->Style[Framed["Range versus Angle of Elevation"],26,Red,Background->Yellow]]

Motion with Linear Resistance--A Good Start

x''=-k x'           x[0]=0,     x'[0]=v*cos θ
y''=-g-k y'            y[0]=0,    y'[0]=v*sin θ

Solve the DE System

Clear[x,y];
paramsol=DSolve[{x''[t]==-k x'[t],y''[t]==-g-k y'[t],x[0]==0,y[0]==0,x'[0]==v Cos[θ],y'[0]==v Sin[θ]},{x[t],y[t]},t]

{x[t_],y[t_]}=FullSimplify[{x[t],y[t]}/.paramsol[[1]]]

Animate the Solution

Manipulate[ParametricPlot[{{(((1-(E^(-k t))) v Cos[θ])/k),((g-g k t+k v Sin[θ]-(E^(-k t)) (g+k v Sin[θ]))/(k^2))}}/.{g->32.2,v->50},{t,0,3},AxesLabel->{x,y},PlotRange->{{0,55},{0,30}},ImageSize->Large,PlotStyle->Thick,PlotLabel->Style[StringForm["Resistance=`` and Launch Angle=``",PaddedForm[k,4],PaddedForm[θ,4]],15,Red, Bold]],{{k,1.250},0.3,5.3},{{θ,π/4.},0.001,(π/2),.01}]

Start to Find the Range--When is y[t]=0?

y[t]
tvals=Solve[y[t]==0,t]   (* Impact time *)

The Lambert W  Function (alias ProductLog)

An Inverse to a Very Common Function

Plot[x Exp[x],{x,-4,2},PlotRange->{-.5,3},PlotLabel->"Graph of w*(E^w)",PlotStyle->Thickness[0.01],Ticks->{Automatic,{((-1)/E),1,2,3}}]

W=ProductLog;      (* In Mathematica  *)
(Subscript[W, -1])[x_]=ProductLog[-1,x];

Show[Plot[Tooltip[W[x],"W:[-(1/E),∞)->[-1,∞)",LabelStyle->Directive[Red,Large]],{x,((-1)/E),4},PlotStyle->{Red,Dashed,Thickness[0.01]}],Plot[Tooltip[(Subscript[W, -1])[x],"\!\(\*FormBox[
RowBox[{
RowBox[{SubscriptBox["W", 
RowBox[{"-", "1"}]], ":", 
RowBox[{"[", 
RowBox[{
RowBox[{"-", FractionBox["1", "E"]}], ",", "0"}], "]"}]}], "->", 
RowBox[{"(", 
RowBox[{
RowBox[{"-", "∞"}], ",", 
RowBox[{"-", "1"}]}], "]"}]}],
TraditionalForm]\)",LabelStyle->Directive[Purple,Large]],{x,((-1)/E),0},PlotStyle->{Purple,Thickness[0.01]}],
PlotRange->{-10,1},PlotLabel->"The Two Real Branches of Lambert W"]

Some Useful Properties of Lambert W

•  W(x*(e^x)) is defined for all x, but W(x*(e^x))=x only for x≥-1

•  x=W(x)*(e^(W(x))) for x∈[-(1/e),∞)  and hence (e^(-W(x)))=((W(x))/x)	

•  W'(x)=((W(x))/(x(1+W(x))))

Use Lambert W to Solve New Classes of Equations

Find solution (with a*d≠0) to

	a*t+b+c*(e^(d*t))=0


Result:      t=-(b/a)-(1/d)*W(((c*d*(e^(-((b*d)/a))))/a))

Solve[a*t+b+c*(E^(d*t))==0,t]

The Desired Range Function

Lambert W Applied to Our Projectile

tvals
x[t]
R[θ_]=x[t]/.tvals[[1]]

Further Simplification is Possible

Let u=-1-((k v)/g)sin θ  and note that (e^(-W(u (e^u))))=((W(u (e^u)))/(u (e^u))) for all u≤-1 (i.e., θ∈[0,π]).

We get   R(θ)=(1/k)v cos(θ)(1-((W(u (e^( u))))/u))   or

               R(θ)=(1/k)v cos(θ)(1-W((-1-((k v)/g)sin(θ)) (e^( -1-((k v)/g)sin(θ))))/(-1-((k v)/g)sin(θ)))

Range as Function of Launch Angle

Manipulate[Plot[(1/k)(1-(E^(-((g+g ProductLog[-(((E^(-1-((k v Sin[θ])/g))) (g+k v Sin[θ]))/g)]+k v Sin[θ])/g)))) v Cos[θ]/.{g->32.2,v->50},{θ,0,(π/2)},PlotRange->{0,60},
PlotStyle->Thick,ImageSize->Large,Ticks->{Range[0,(π/2),(π/12)],True},AxesLabel->{ "Launch Angle","Range"}],{{k,1.250,"Resistance"},0.3,5.3, Appearance->"Labeled"}]

Does Solution Reduce to No Resistance Case?

Recall that R(θ)=(1/k)v cos(θ)(1-((W(u (e^( u))))/u)) and u=-1-((k v)/g)sin(θ)

(lim_(u->-(SuperMinus[1])))R(θ)=((v^2)/g)sin(θ)cos(θ)* (lim_(u->-(SuperMinus[1])))((W(u*(E^( u)))-u)/(u(u+1)))
 
	              = ((v^2)/g)sin(θ)cos(θ)* (lim_(u->-(SuperMinus[1])))((W(u*(E^( u)))+1-(u+1))/(u(u+1)))

	              = ((v^2)/g)sin(θ)cos(θ)*(1+ (lim_(u->-(SuperMinus[1])))((W(u*(E^( u)))+1)/(u(u+1))))
	              = ((v^2)/g)sin(θ)cos(θ)* (1-(lim_(u->-(SuperMinus[1])))((W(u*(E^u))-(-1))/(u-(-1))))
	               
	              = ((v^2)/g)*2sin(θ) cos(θ)      (WE  HOPE)

Mathematica Can Evaluate the Limit, But ...........

Limit[((W[u*(E^u)]+1)/(u+1)),u->-1,Direction->1]

An "Inverse Function" Limit Theorem

Statement

Theorem 1.   Let f be a nonconstant real-analytic function in a neighborhood of (Subscript[x, 0]).  Suppose f has a local extremum at (Subscript[x, 0]).  Then there is a neighborhood of (Subscript[x, 0]) such that f is strictly monotonic on  [(Subscript[x, 0]),(Subscript[x, 0])+h] and on [(Subscript[x, 0])-h,(Subscript[x, 0])].  Let  g be the inverse function of f on [(Subscript[x, 0]),(Subscript[x, 0])+h].  Then y(x)=g(f(x)) is defined on  [(Subscript[x, 0])-k,(Subscript[x, 0])] for some   k>0 and (lim_(x->(SuperMinus[(Subscript[x, 0])])))(((y(x)-(Subscript[x, 0]))/(x-(Subscript[x, 0]))) )= -1. 

Note that this is the left-side derivative of y(x) because y((Subscript[x, 0]))=(Subscript[x, 0]).

Proof Highlights

•  Write f(x)=(Subscript[a, 0])+(∑_(i=N)^∞)(((Subscript[a, i])(x-(Subscript[x, 0])))^i), (Subscript[a, N])≠0

•   Let F(x)=(∑_(i=N)^∞)(((Subscript[a, i])(x-(Subscript[x, 0])))^(i-N)), so ((f(x)=(Subscript[a, 0])+(x-(Subscript[x, 0])))^N)F(x) and F((Subscript[x, 0]))=(Subscript[a, N])≠0

•  Note that "local extremum at (Subscript[x, 0])" forces N to be even

•  Since f(y(x))=f(g(f(x)))=f(x) ∀ x∈[(Subscript[x, 0])-k,(Subscript[x, 0])], get 

      (Subscript[a, 0])+(((y(x)-(Subscript[x, 0])))^N)F(y(x))=(Subscript[a, 0])+(((x-(Subscript[x, 0])))^N)F(x) and hence ((((y(x)-y((Subscript[x, 0]))))^N)/(((x-(Subscript[x, 0])))^N))=((F(x))/(F(y(x))))

•  Take (N^th) roots (even) and use ((y(x)-y((Subscript[x, 0])))/(x-(Subscript[x, 0])))<0 to get 
		(lim_(x->(SuperMinus[(Subscript[x, 0])])))(((y(x)-(Subscript[x, 0]))/(x-(Subscript[x, 0]))) )=(lim_(x->(SuperMinus[(Subscript[x, 0])])))((((F(x))/(F(y(x))))^(1/N)) )=-1.

Corollary:

Apply to Lambert W at (Subscript[x, 0])=-1 and, indeed, (lim_(u->-(SuperMinus[1])))((W(u*(e^u))-(-1))/(u-(-1)))=-1.

The Inverse Range Problem

Theorem 2. For fixed angle θ the range values decrease as the resistance k increases. Also, for any resistance k>0 there is a maximum range value, M, that occurs for a unique angle (Subscript[θ, max])<(π/4). Finally, for all nonnegative ranges r<M, there are exactly two angles θ∈[0,(π/2)] that satisfy R(θ)=r, one on each side of (Subscript[θ, max]).

A Closed Form for the Maximizing Range Angle

Theorem 3.  (Found independently by Packel-Yuen and Groetsch, 2003)
The angle (Subscript[θ, max]) that gives the maximum range for a given  v,g,k depends only on α=((k v)/g) and is given by the formula  (Subscript[θ, max])=ArcSin[(α/((e^(1+W((((α^2)-1)/e))))-1))] .

Plot[ArcSin[(α/((E^(1+W[(((α^2)-1)/E)]))-1))],{α,0,50},PlotRange->{0,(π/4)},PlotLabel->Style["Maximum Range Angle as function of α",18],
Ticks->{True,Range[0,(π/4),(π/12)]},PlotStyle->Thick]

Experimental Mathematics

Part of the statement of philosophy of the Journal of Experimental Mathematics, a journal started in 1992.

"Experiment has always been, and increasingly is, an important method of mathematical discovery. ....  Yet this tends to be concealed by the tradition of presenting only elegant, well-rounded and rigorous results. 

While we value the theorem-proof method of exposition, and while we do not depart from the established view that a result can only become part of mathematical knowledge once it is supported by a logical proof, we consider it anomalous that an important component of the process of mathematical creation is hidden from public discussion. It is to our loss that most of us in the mathematical community are almost always unaware of how new results have been discovered. ....

Experimental Mathematics was founded in the belief that theory and experiment feed on each other, and that the mathematical community stands to benefit from a more complete exposure to the experimental process. The early sharing of insights increases the possibility that they will lead to theorems: an interesting conjecture is often formulated by a researcher who lacks the techniques to formalize a proof, while those who have the techniques at their fingertips have been looking elsewhere. Even when the person who had the initial insight goes on to find a proof, a discussion of the heuristic process can be of help, or at least of interest, to other researchers. There is value not only in the discovery itself, but also in the road that leads to it."

References

____________, Time for a new elementary function?, FOCUS 20 (2000) 2.

Jonathan M. Borwein and Robert M. Corless, Emerging tools for experimental mathematics, Amer. Math. Monthly 106 (1999) 889-909.

R. M. Corless, G. H. Gonnet, D. E. G. Hare, D. J. Jeffrey, and D. E. Knuth, On the Lambert W function, Adv. Comput. Math. 5 (1996) 329-359.

C. W. Groetsch, Tartaglia's inverse problem in a resistive medium, Amer. Math. Monthly 103 (1996) 546-551.

Edward W. Packel and David S. Yuen, Projectile motion with resistance and the Lambert W function, Coll. Math. Journal (2004) 337-350.