Calculus and Geometry Demonstrations

Helen Papadopoulos

Torrey Pines High School

Volumes of Revolution: Cylindrical Shell Method

This project is designed to help calculus students visualize the cylindrical shell method of finding volumes of revolution. It uses the example of rotating f(x)= 2(x^2) - (x^3) around the y-axis.

Rotating the 2-D Function

To visualize solids of revoution we first need to rotate the function around the desired axis.

f[x_] := 2 x^2 - x^3;
Row[{Show[
      Plot[{f[x], 0}, {x, 0, 2}, PlotStyle -> Black, 
    Filling -> Axis, 
        FillingStyle -> Orange, ImageSize -> 325],
      Graphics[Text[2 x^2 - x^3, {1.25, .6}]]], 
    Manipulate[
   Show[Graphics3D[],
     RevolutionPlot3D[f[t], {t, 0, 2}, {z, 0, θ}, 
         PlotStyle -> Orange], 
    PlotRange -> {{-2, 2}, {-2, 2}, Automatic}, 
    Axes -> True], {θ, .01, 2 Pi}]}]

Volumes of Revolution (Continued)

The Shells

The concentric cylinders are the shells.  As we manipulate dx, we get more and more shells, and as we manipulate xmax, the shells fill from 0 out to two, forming the solid of revolution.

f[a_]:=2a^2-a^3;
Manipulate[
Row[{
Show[Plot[{f[x],0},{x,0,2},PlotStyle->Black,Filling->Axis,FillingStyle->Directive[Lighter[Gray,.9]],ImageSize->300],Graphics[{
Table[{Red,Line[{{x1,0},{x1,f[x1]}}]},{x1,0,xmax,dx}]
},PlotRange->{{0,3},{0,2}},Axes->True,ImageSize->300]],
Show[If[ShowPlot, {RevolutionPlot3D[f[t], {t, 0, 2}, {z, 0, 2Pi}, 
      PlotStyle -> Opacity[0.8],Mesh->ShowMesh,MaxRecursion -> 1]},{}], 
   Evaluate[Table[ParametricPlot3D[{x*Cos[u], x*Sin[u], v}, {u, 0, 2Pi}, 
      {v, 0, f[x]+.0001}, Mesh -> False, PlotStyle -> Red, 
      ImageSize -> 300, MaxRecursion -> 1], {x,0, xmax, dx}]],Graphics3D[],PlotRange->{{-2,2},{-2,2},{0,1.2}},BoxRatios->Automatic,Axes->True,Boxed->False,ImageSize->300,AxesEdge->{{-1,-1},{-1,-1},{-1,-1}}]}],
{{dx,0.3},0.2,1},
{{xmax,2},0,2}, 
  {{ShowPlot,False}, {True, False}, Checkbox,ControlPlacement->Left},
{{ShowMesh,False},{True,False},Checkbox,ControlPlacement->Left}
]

Areas of Trapezoids/Parallelograms

Where did those area formulas come from? This manipulate was my first attempt at visually showing how parallelograms can be rearranged to create rectangles that match their area formula.

Manipulate[
Graphics[{
{Pink,EdgeForm[Dashed],Rectangle[{-1,-.5},{1,.5}]},
Translate[{Translate[{Pink,EdgeForm[Dashed],Polygon[{{1,.5},{2,-.5},{1,-.5}}]},{split,0}],
Translate[Translate[{Pink,EdgeForm[Dashed],Polygon[{{-1,-.5},{-2,.5},{-1,.5}}]},{-split,raise}],{move,close}]},{finish,0}]
},PlotRange->{{-3.5,3.1},{-1,2}}],
{split,0,1},{raise,0,1},{move,0,5},{close,0,-1},{finish,0,-1}]

But this had too many controls, so I changed it to highlight the moving triangles instead.  The final version included a parallelogram, an isoceles trapezoid, and a regular trapezoid.  It has been published as a demonstration:


Areas of parallelograms/trapezoids demonstration