Set up basic parameters...

ϵ=0.05

r=1-ϵ

θ=2ArcSin[1/(2r)]

p2d=NestList[RotationMatrix[θ].#&,{r,0},4];

Produce the 5 subscripted P points from the article...

p=Append[#,0]&/@p2d;

m=Sqrt[1-r*r]

Produce the two m points above (m1) and below (m2) the center of the circle...

m1={0,0,m};m2={0,0,-m};

FindT[m_,p1_,p2_]:=Cases[{x,y,z}/.Solve[SquaredEuclideanDistance[p1,{x,y,z}]== 1 &&SquaredEuclideanDistance[p2,{x,y,z}] ==1 &&
SquaredEuclideanDistance[m,{x,y,z}]== 1, {x, y, z}],_?(#[[3]]>0&)][[1]]

Determine the original subscripted T points from the article...

t1=FindT[m2,p[[1]],p[[2]]];
t2=FindT[m1,p[[2]],p[[3]]];
t3=FindT[m2,p[[3]],p[[4]]];t4=FindT[m1,p[[4]],p[[5]]];

CoplanarDet[p1_,p2_,p3_,p4_]:=Det[Append[#,1]&/@{p1,p2,p3,p4}]

Coplanar[p1_,p2_,p3_,p4_]:=CoplanarDet[p1,p2,p3,p4]==0

Produce the (Subscript[T, 4])' which is coplanar with (Subscript[T, 1]), (Subscript[T, 2]), and  (Subscript[T, 3])...

t4pCand = {x,y,z}/.Solve[Coplanar[t1,t2,t3,{x,y,z}] &&
SquaredEuclideanDistance[{x,y,z},p[[4]]]==1&&
SquaredEuclideanDistance[{x,y,z},m1]==1,{x,y,z}]

t4p=If[SquaredEuclideanDistance[t4pCand[[1]], t3]>SquaredEuclideanDistance[t4pCand[[2]], t3],
t4pCand[[1]], t4pCand[[2]]]

(Subscript[P, 5])' is where (Subscript[P, 5]) gets moved to when the rotation to make (Subscript[T, 4]) coplanar with the other points is made.

p5p=Cases[{x,y,z}/.Solve[SquaredEuclideanDistance[p[[4]],{x,y,z}]== 1 &&SquaredEuclideanDistance[m1,{x,y,z}] ==1 &&
SquaredEuclideanDistance[t4p,{x,y,z}]== 1, {x, y, z}],_?(#[[3]]<0&)][[1]]

TetrahedronQ[p1_,p2_,p3_,p4_]:=
EuclideanDistance[p1,p2]==1 &&
EuclideanDistance[p1,p3]==1 &&
EuclideanDistance[p1,p4]==1 &&
EuclideanDistance[p2,p3]==1 &&
EuclideanDistance[p2,p4]==1 &&
EuclideanDistance[p3,p4]==1

Verify that all the tetrahedrons are indeed tetrahedral...

TetrahedronQ[p[[1]],p[[2]],m2,t1] && TetrahedronQ[p[[2]],p[[3]],m1,t2] &&
TetrahedronQ[p[[3]],p[[4]],m2,t3] &&
TetrahedronQ[p[[4]],p5p,m1,t4p]

...and that the T points are sufficiently coplanar...

CoplanarDet[t1,t2,t3,t4p]

Tetrahedron[p1_,p2_,p3_,p4_]:=GraphicsComplex[{p1,p2,p3,p4},
Polygon[{{1,2,3},{1,2,4},{2,3,4},{1,3,4}}]]

BaseStructure={
Tetrahedron[p[[1]],p[[2]],t1,m2],
Tetrahedron[p[[2]],p[[3]],t2,m1],
Tetrahedron[p[[3]],p[[4]],t3,m2],
Tetrahedron[p[[4]],p5p,t4p,m1]};

Show the base structure...

Graphics3D[BaseStructure]

Get the mirror transform which mirrors points across the plane the (Subscript[T, i]) lie in...

TPlaneReflectFirst=ReflectionTransform[Cross[t2-t1,t2-t3],t2];

ReflectGP[s_,t_]:=Flatten[s/.GraphicsComplex[{p1_,p2_,p3_,p4_},polys__]->
{GraphicsComplex[{p1,p2,p3,p4},polys],
GraphicsComplex[t/@{p1,p2,p3,p4},polys]},1]

Reflect all the tetrahedra in the base structure across this plane and show the result...

FirstReflectStruct=ReflectGP[BaseStructure,TPlaneReflectFirst];

Graphics3D[FirstReflectStruct]

Verify that the proper P points are coplanar and reflect the tetrahedra across the plane they lie in

p1p=TPlaneReflectFirst[p[[1]]];p5pp=TPlaneReflectFirst[p5p];

CoplanarDet[p[[1]],p1p,p5p,p5pp]

TPlaneReflectSecond=ReflectionTransform[Cross[p5p-p1p,p5p-p5pp],p5p];

SecondReflectStruct=ReflectGP[FirstReflectStruct,TPlaneReflectSecond];

Show the final result...

Graphics3D[SecondReflectStruct]