Profit Function

Hal R. Varian
June, 1992

Profit function

Recall the profit function for the Cobb-Douglas technology that we derived in the last chapter.   We will repeat the derivation here without comment, since we already saw it done in the previous chapter.

f[x1_,x2_] := (x1^(1/4))*(x2^(1/4))
Profit[x1_,x2_,p_,w1_,w2_] := p*f[x1,x2] - w1*x1 - w2*x2
solution=Solve[{D[Profit[x1,x2,p,w1,w2],x1]==0, 
                D[Profit[x1,x2,p,w1,w2],x2]==0},
                {x1,x2}][[1]]
pi[p_,w1_,w2_] := Evaluate[Profit[x1,x2,p,w1,w2]/.solution]
pi[p,w1,w2]

Convexity of the profit function

Let's graph this function to make sure that it is really convex.  First we'll fix w1 and w2 and look at how the function behaves with respect to p.

Plot[pi[p,1,1],{p,1,4}]

Now let's look at a 3D-plot and a contour plot, fixing p at 1.

Plot3D[pi[1,w1,w2],{w1,1,50},{w2,1,50}]

ContourPlot[pi[1,w1,w2],{w1,1,50},{w2,1,50},ContourShading->False]

Hotelling's identity

Finally, we want to verify that we satisfy Hotelling's identity, so we'll compute the derivatives of the profit function with respect to w1  and compare it to the factor demand functions.

deriv[p_,w1_,w2_]:=-Evaluate[Simplify[D[pi[p,w1,w2],w1]]]
deriv[p,w1,w2]
factorDemand1[p_,w1_,w2_] := Evaluate[Simplify[x1/.solution]]
factorDemand1[p,w1,w2]

It is not obvious that these expressions are equal to each other.  But if we apply the right simplification, we see that Hotelling's identity works.

PowerExpand[deriv[p,w1,w2]]