Prediction of Conversion 
with an Axially-Dispersed 
Plug Flow Reactor    
Author's Data: Housam BINOUS
Department of Chemical Engineering
National Institute of Applied Sciences and Technology
Tunis, TUNISIA
Email: binoushousam@yahoo.com

Analytical solution for the conversion of an isothermal axially dispersed PFR accomplishing a first order reaction.

Clear[u,Di,k,L];

solution = 
      First[DSolve[{0 == 
                1/Pe D[c[z], {z, 2}] - D[c[z], {z, 1}] - Da c[z]}, c[z], 
            z]] // Simplify

Conc=c[z]/.solution/.C[1]->C1/.C[2]->C2//Factor

CONCENTRATION = Conc /. (Sqrt[4 Da + Pe]) -> q (Sqrt[Pe])

Danckwerts boundary conditions for the so-called "closed" configuration

sol=Solve[{(D[%,{z,1}]/.z->1)==0,(%/.z->0)-1/Pe (D[%,{z,1}]/.z->0)==1},{C1,C2}]//Simplify

Conversion

CONCENTRATIONEXIT=CONCENTRATION/.z->1/.sol//Simplify

X=First[1-CONCENTRATIONEXIT]

Peclet Number

Pe=(u L)/Di

Damkohler number

Da=k L/u

Numerical evaluation

Di=0.005;k=0.01;L=1;u=0.01;

Da

Pe

q = (Sqrt[1 + 4 Da/Pe])

X

Plot of concentration profile in the PFR

plt1=Plot[CONCENTRATION/.sol,{z,0,1},PlotStyle->RGBColor[1,0,0]]

Numerical solution for the conversion of an isothermal axially dispersed PFR accomplishing a second order reaction. The Danckwerts boundary conditions for the so-called "closed" configuration are used. We use the shooting method since it is a split-boundary-value problem. Damkohler number (Da) and Inverse Peclet number (1/Pe) must have same order of magnitude unless one gets a stiff ODE which cannot be solved easily.

Di=0.005;k=0.01;L=1;u=0.01;

Da

Pe

SOL[λ_]:=NDSolve[{0 == 
              1/Pe D[c[z], {z, 2}] - D[c[z], {z, 1}] - Da c[z]^2, c'[
                0] == λ, -1/Pe λ + c[0] == 
              1},c[z],{z, 0, 1},Method->StiffnessSwitching]

BCend[λ_?NumericQ]:=Flatten[(D[c[z]/.SOL[λ],{z,1}])/.z->1]

ξ=FindRoot[BCend[λ]==0,{λ,1,2},MaxIterations-> 1000][[1,2]];

ξ

BCend[ξ]

Conversion

1-c[z]/.SOL[ξ]/.z->1

Plot of concentration profile in the PFR

CONC=First[c[z]/.SOL[ξ]]

plt2=Plot[CONC,{z,0,1},PlotStyle->RGBColor[0,0,1]]

Comparing first and second order reactions

Show[plt1,plt2]