Expression of Volumetric Flow Rate for Pipe Flow 
of Bingham and Power Law Fluids
Author's Data: Housam BINOUS
Department of Chemical Engineering
National Institute of Applied Sciences and Technology
Tunis, TUNISIA
Email: binoushousam@yahoo.com

Volumetric Flow Rate for Pipe Flow of a Bingham Fluid

Calculation of shear stress using boundary condition:(Subscript[τ, rz])(0) = 0

sol1 = 
      DSolve[D[r (Subscript[τ, rz])[r], {r, 1}] ==  PG r, (Subscript[τ, rz])[r], 
        r]

(Subscript[τ, rz])[r] = sol1[[1, 1, 2]] /. C[1] -> 0

Calculation of velocity (Subscript[v, z])(r) between r=((-2 (Subscript[τ, 0]))/PG) and r=a using boundary condition: (Subscript[v, z])(a) = 0

sol2 = 
      DSolve[D[(Subscript[v, z])[r], {r, 
              1}] ==  ((Subscript[τ, rz])[r] + (Subscript[τ, 0]))/μ, (Subscript[v, z])[r], 
        r]

(Subscript[v, z])[r] = 
      sol2[[1, 1, 2]] /. 
        C[1] -> -((PG (a^2))/(4 μ)) - ((a (Subscript[τ, 0]))/μ)

Calculation of Q1 flow rate between r=((-2 (Subscript[τ, 0]))/PG) and r=a where velocity is given by (Subscript[v, z])(r)

Q1 = 
      Integrate [
        2 Pi r (Subscript[v, z])[r], {r, -2 (Subscript[τ, 0])/PG, a}]

Calculation of constant velocity (Subscript[v, 0]) between r=0 and r=((-2 (Subscript[τ, 0]))/PG) using boundary condition: (Subscript[v, 0]) = (Subscript[v, z])(a)

(Subscript[v, 0]) = 
      1/μ PG (r^2 - a^2)/4 + (Subscript[τ, 0])/μ (r - a) /. 
        r -> -2 (Subscript[τ, 0])/ PG

Calculation of Q2 flow rate between r=0 and r=((-2 (Subscript[τ, 0]))/PG) where velocity is constant equal to (Subscript[v, 0])

Q2 = 
      Integrate [2 Pi r (Subscript[v, 0]), {r, 0, -2 (Subscript[τ, 0])/PG}]

Total Flow Rate is equal to Q1+Q2

Q1 + Q2 // Expand

Volumetric Flow Rate for Pipe Flow of a Power Law Fluid

Clearing previous shear stress and velocity expressions

(Subscript[τ, rz])[r] =.

(Subscript[v, z])[r] =.

Calculation of shear stress using boundary condition:(Subscript[τ, rz])(0) = 0

sol3 = 
      DSolve[D[r (Subscript[τ, rz])[r], {r, 1}] ==  PG r, (Subscript[τ, rz])[r], 
        r]

(Subscript[τ, rz])[r] = sol1[[1, 1, 2]] /. C[1] -> 0

Calculation of velocity (Subscript[v, z])(r) between r=0 and r=a using boundary condition: (Subscript[v, z])(a) = 0

sol4 = 
      DSolve[D[(Subscript[v, z])[r], {r, 
              1}] ==  -(-(Subscript[τ, rz])[r]/k)^(1/n), 
        (Subscript[v, z])[r], r]

(Subscript[v, z])[r] = 
      sol4[[1, 1, 2]] /. 
        C[1] -> (((2^(-1/n)) n a (((-((PG a)/k)))^((1/n))))/(1 + n))

Calculation of Q flow rate between r=0 and r=a where velocity is given by (Subscript[v, z])(r)

Q = Integrate[2 Pi r (Subscript[v, z])[r], {r, 0, a}]