Creating a Random Walk

The function RandomWalk generates a d-dimensional random walk of n steps starting at the origin.

RandomWalk[n_,d_]:=NestList[(#+(-1)^Table[Random[Integer],{d}])&,Table[0,{d}],n];

Here are the points in a walk of 100 steps in 3-space.

data=RandomWalk[100,3];

Plotting the walk

We can plot the walk. If we first select the first and last points we can place markers on those points.

Your first point in the walk is:

firstpoint=data[[1]]

And your last one is:

lastpoint=data[[101]]

lastpoint2=Last[data]

In this plot the first point is colored red and the last one is colored blue.

Show[Graphics3D[{{Hue[0], PointSize[.02], Point[firstpoint]},{Hue[.7], PointSize[.02],Point[lastpoint]},Line[data]}]];

An animation of our walk

First a function to facilitate the animation.

createAnimation[grList_List] :=
  Module[
    {theCellGroup},
    theCellGroup =CellGroupData[
        Append[(Cell[
                  GraphicsData["PostScript", DisplayString[#1]], "Graphics",
                  CellTags -> {"AnimationGroup"}
                  ] & ) /@ grList,
          Cell[BoxData[ButtonBox[ "Animate Graphics",
                ButtonFunction :> FrontEndExecute[ {
                      NotebookFind[ ButtonNotebook[],"AnimationGroup",All, CellTags],
                      SelectionAnimate[ ButtonNotebook[]]} ],
                ButtonEvaluator -> None,
                Active -> True ] ],
            TextAlignment -> Center] ], Closed ];
    NotebookWrite[EvaluationNotebook[], Cell[theCellGroup]]
    ]

The function createAnimation calls for a list of graphics objects for its argument. Here we create such a list and append a second copy of the last frame to cause the animation to hesitate at the final point before starting over.

grph=Append[Table[Show[Graphics3D[{{Hue[0], PointSize[.02], Point[firstpoint]},{Hue[.7], PointSize[.02],Point[lastpoint]},{Hue[.55], PointSize[.03],Point[data[[i]]]},Line[data]}],ImageSize -> 5 72,DisplayFunction -> Identity],{i,101}],Show[Graphics3D[{{Hue[0], PointSize[.02], Point[firstpoint]},{Hue[.7], PointSize[.02],Point[lastpoint]},{Hue[.55], PointSize[.03],Point[data[[101]]]},Line[data]}],ImageSize -> 5 72,DisplayFunction -> Identity]];

This creates the animation and a button to activate the animation.

createAnimation[grph]