Solution of quintics via Klein

We assume that the general quintic 
a0 x^5 + a1 x^4 + a2 x^3 + a3 x^2 + a4 x + a5 = 0
has been  reduced to a  principal quintic
y^5 + 5a y^2 + 5 b y + c = 0 by an appropriate Tschirnhaus transformation. 
(The factors 5 are historical.)
To solve for the roots yi of the principal quintic we make the following "ansatz" (educated guess):
yi = l f /H Wi + m f^3/H/T ti Wi  (i = 0, ..., 4)
The quantities Wi,  f, H, T and ti are:

f[u_, v_] = u v (u^10 + 11 u^5 v^5 - v^10);
H[u_, v_] = -u^20 - v^20 + 228(u^15 v^5 - u^5 v^15) - 494 u^10 v^10;
T[u_, v_] = u^30 + v^30 + 522 (u^25 v^5 - u^5 v^25) - 
                            10005 (u^20 v^10 + u^10 v^20);
W[k_, u_, v_] = -e^(4k) u^8 + e^(3k) u^7 v - 7 e^(2k) u^6 v^2 - 
            7 e^k u^5 v^3 + 7 e^(4k) u^3 v^5 - 
            7 e^(3k) u^2 v^6 - e^(2k) u v^7 - e^k v^8;
t[k_, u_, v_] = e^(3k) u^6 + 2 e^(2k) u^5 v - 5 e^k u^4 v^2 - 
             5e^(4k) u^2 v^4 - 2 e^(3k) u v^5 + e^(2k) v^6; 
e = Exp[2Pi I/5];

The variables u and v in the above equations are given by:

u[Z_] := (12)^(1/20) 1/(1728Z)^(1/60)*
                     Hypergeometric2F1[-1/60,29/60,4/5,1728 Z];
v[Z_] := 1/(12^11)^(1/20) (1/(1728 Z))^(-11/60)*
                     Hypergeometric2F1[11/60,41/60,6/5,1728 Z];

Solving the following system of four algebraic equations (a, b, and c come from the principal quintic) determines m, l, and Z (see below) :

{a V == 8 l^3 + l^2 m + 72 l m^2 Z + m^3 Z,
 b V == - l^4 + 18 l^2 m^2 Z + l m^3 Z + 27 m^4 Z^2,
 c V ==   l^5 - 10 l^3 m^2 Z + 45 l m^4 Z^2 + m^5 Z^2, 
 1 + V Z == 1728 Z}

The variables u and v are a solution of the icosahedral equation lhsIcoEq[u, v] = 0.

lhsIcoEq[u_, v_, Z_]:=
     u^5 v^5 (u^10 + 11 u^5 v^5 - v^10)^5 - 
     (u^30 + v^30 - 10005 (u^20 v^10 + u^10 v^20) + 
     522 (u^25 v^5 - u^5 v^25))^2 Z

The icosahedral equation is sometimes also written in the form:

lhsIcoEq[z, 1, Z]

However, it is more appropriate to keep u and v for numerical reasons.
Here is a numerical check:

lhsIcoEq[ N[u[2.-0.7I]], N[v[2.-0.7I]], 2.-0.7I ] // Chop

That the above ansatz reduces to the above algebraic system in m, l, Z, and V can be verified in a straightforward but rather lengthly calculation. That u[Z] and v[z] are solutions of the icosahedral equation can be verified by the monodromy group properties of the solutions of the hypergeometric differential equation.
Putting all this together we have the following implementation for Klein's approach for solving quintics:

KleinSolve[p_ == 0, y_] :=
Module[{a, b, c, n, l, m, w, Z, fm, Hm, Tm, um, vm, sol},
{a, b, c} = 
     ({1/5, 1/5, 1} (Coefficient[p, y, #]& /@ {2, 1, 0}))/
                     Coefficient[p, y, 5] ;
l = (-#2/#1/2+Sqrt[#2^2/#1^2/4-#3/#1])&[
   (a^4+a b c-b^3),-(11a^3 b-a c^2+2b^2c),(64 a^2 b^2-
                                    27a^3c-b c^2)];
w = (l b + c)/a; V=(l^2-3w)^3/(l c-w b);
Z = 1/(1728-V); m = (V a-8 l^3-72 l w)/(l^2+w);
um = u[Z]; vm = v[Z]; fm = f[um, vm]; 
Hm = H[um, vm]; Tm = T[um, vm];
{y->#}& /@  Sort[Table[l fm W[k, um, vm]/Hm +
          m fm^3 t[k, um, vm] W[k, um, vm]/Tm/Hm,{k, 0 ,4}]] ] /;
                 MatchQ[CoefficientList[p, y],{_, _ ,_, 0, 0, _}]

Here is a numerical example for solving a quintic using Klein's approach:

KleinSolve[y^5 + 5.I y^2 -12. y + 1.- I == 0, y] //N // Chop // Sort

NSolve[y^5 + 5.I y^2 -12. y + 1.- I == 0, y]