Solution of quintics based on differential equations

Cockle (1860) and Harley (1862) developed a method for solving algebraic equations based on differential equations..

First example

We illustrate their approach with the quintic equation:

eqn = t[rho]^5 - t[rho] - rho == 0;

Each root is a function of the parameter rho. The differential resolvent of this quintic 
is a linear differential equation of order 4 of the form:

diffeqn = a1 t''''[rho] + a2 t'''[rho] + a3 t''[rho] + 
	a4 t'[rho] + a5 t[rho] + a6  == 0

The coefficients aj are polynomial functions in rho. We will find them explicitly in the next several steps. We differentiate the quintic equation eqn with respect to rho:

deriv = Flatten[Table[ Solve[ D[eqn, {rho, k}], 
		D[t[rho], {rho, k}]], {k, 1, 4}]]

We substitute these derivatives  into the differential equation diffeqn:

algeqn = Simplify[diffeqn //. deriv]

We replace powers t[rho]^k with exponents k greater than 4 using the original quintic equation:

algeqn = Collect[Numerator[algeqn], t[rho] ]

This gives a new algebraic equation with respect to t[rho] of degree 4. We set the coefficients of the powers of t[rho] to zero:

algeqn = (# == 0)& /@ CoefficientList[algeqn, t[rho]]

This is a system of linear equations for the coefficients aj. Its solution is:

coeffs = Solve[algeqn, {a1,a2,a3,a4,a5,a6}] // Simplify

Hence the differential resolvent is:

diffeqn = First[diffeqn /. coeffs]

We solve this differntial equation:

<<Calculus`DSolve`

sol = DSolve[diffeqn, t[rho], rho]

This is a general solution to the differential equation that depends on the four parameters C[1], C[2],, C[3], C[4]. We will find the values of these parameters so that this solution will also satisfy the original quintic. To do this we could substitute this solution into the original quintic and solve the resulting equation. However, it is enough to substitute the series expansion of the solution sol at rho = 0, where the main term of the generalized hypergeometric function is 1:

approximation = sol /. HypergeometricPFQ[w__] -> 1

algeqn = eqn /. approximation

Now we collect like terms in rho and set the coefficients to zero. We solve the resulting system of four linear equations  for the coefficients C[j]:

system = Map[# == 0 &, 
	Take[CoefficientList[First[algeqn], rho], 4]]

coeffs = Solve[system, Table[C[j], {j, 4}]]

Finally we obtain the five roots of the given quintic:

First[solution] /. coeffs

Second example

Here we consider another example with an arbitray parameter z:

x^5 - 5 x^3 + 5 x - z = 0

Surprisingly this equation is solvable by radicals for any values of z. We construct the differential resolvent  associated with this equation as above:

25 (4 - z^2) x''[z] - 25 z x'[z] + x[z] == 0

Its general solution is:

DSolve[resolvent, x[z], z]

To determine the constants C[1] and C[2] we substitute this solution into the quintic and expand with respect to z at z = 0. Equating the first two terms of the expansion to zero, we obtain a system of two equations in C[1] and C[2].  Solving this system, we get the roots of the given quintic:

{{x[z] -> 2 Sin[1/5 ArcSin[z/2]]},

 {x[z] -> -((5 + 5^(1/2))/2)^(1/2) Cos[ArcSin[z/2]/5] + 
         (-1 + 5^(1/2))/2 Sin[ArcSin[z/2]/5]},
	 
 {x[z] -> ((5 + 5^(1/2))/2)^(1/2) Cos[ArcSin[z/2]/5] + 
         (-1 + 5^(1/2))/2 Sin[ArcSin[z/2]/5]},
	 
 {x[z] -> -((5 - 5^(1/2))/2)^(1/2) Cos[ArcSin[z/2]/5] - 
         (1 + 5^(1/2))/2 Sin[ArcSin[z/2]/5]},
	 
 {x[z] -> ((5 - 5^(1/2))/2)^(1/2) Cos[ArcSin[z/2]/5] - 
         (1 + 5^(1/2))/2 Sin[ArcSin[z/2]/5]} }

Cubic and quartic

Cubic and quartic equations can be solved by the same method. 
Consider the cubic:

x^3 - x - z == 0

Its solution is:

{ {x[z] -> -z Hypergeometric2F1[2/3, 1/3, 3/2, 27 z^2/4]},

  {x[z] -> Hypergeometric2F1[1/6, -1/6, 1/2, 27 z^2/4] + 
         z/2 Hypergeometric2F1[2/3, 1/3, 3/2,  27 z^2/4]}, 
        
  {x[z] -> -Hypergeometric2F1[1/6, -1/6, 1/2, 27 z^2/4] + 
         z/2 Hypergeometric2F1[2/3, 1/3, 3/2,  27 z^2/4]} }

Consider the quartic:

x^4 - x - z == 0

Its solution is:

{ {x[z] -> -z HypergeometricPFQ[{1/4, 1/2, 3/4}, {2/3, 4/3}, -256 z^3/27]}, 

  {x[z] -> HypergeometricPFQ[
           {-1/12, 1/6, 5/12}, {1/3, 2/3}, -256 z^3/27] + 
         z/3 HypergeometricPFQ[
             {1/4, 1/2, 3/4}, {2/3, 4/3}, -256 z^3/27] - 
     2 z^2/9 HypergeometricPFQ[
             {7/12, 5/6, 13/12}, {4/3, 5/3}, -256 z^3/27]}, 
  
  {x[z] -> (-1)^(2/3) HypergeometricPFQ[
        {-1/12, 1/6, 5/12}, {1/3, 2/3}, -256 z^3/27] + 
        z/3 HypergeometricPFQ[
            {1/4, 1/2, 3/4}, {2/3, 4/3}, -256 z^3/27] + 
        2 (-1)^(1/3) z^2/9 HypergeometricPFQ[
             {7/12, 5/6, 13/12}, {4/3, 5/3}, -256 z^3/27]}, 
       
  {x[z] -> -(-1)^(1/3) HypergeometricPFQ[
       {-1/12, 1/6, 5/12}, {1/3, 2/3}, -256 z^3/27] + 
          z/3 HypergeometricPFQ[
              {1/4, 1/2, 3/4}, {2/3, 4/3}, -256 z^3/27] - 
          2 (-1)^(2/3) z^2/9 HypergeometricPFQ[
             {7/12, 5/6, 13/12}, {4/3, 5/3}, -256 z^3/27]} }