Steady-State Linear Vibrations

Description

This Notebook examines the behavior of a coupled two-mass system with damping, using Mathematica.  The behavior of the system is examined for different values of the parameters and the conditions for isolation of the first mass are derived.

E

Consider two masses coupled  by a spring and a dashpot.  The first mass is coupled 
to a wall by a second spring. The system is described in Figure 1.

The parameters  k1 and k2 refer to the stiffness of the springs; m1 and m2 are the masses of the blocks;
 d is the dissipation coefficient of the dashpot; and P(t) is a periodic driving force.

By: John M. Novak
Wolfram Research, Inc.
Based on examples from 
Variational and Finite Element Methods: A Symbolic Computation Approach
by A.I. Beltzer

The Equations

The equations of motion governing this system can be derived from basic physics.

The forces acting on the first mass are

spring[1]   = k1 x1[t] + k2(x1[t] - x2[t]);
friction[1] = d (x1'[t] - x2'[t]);
inertia[1]  = m1 x1''[t];

From Newton's first law, the equation of motion,

eqn[1] = inertia[1] + friction[1] + spring[1] == p[t]

Similarly, for the second mass

spring[2]   = k2(x2[t] - x1[t]);
friction[2] = d (x2'[t] - x1'[t]);
inertia[2]  = m2 x2''[t];

eqn[2] = inertia[2] + friction[2] + spring[2] == 0

Assume the system is driven by an external periodic driving force of frequency
omega and magnitude p0.

force = p[t] -> p0 Exp[I omega t];

For a steady-state solution,  x1 and x2 must have a periodic solution with the same 
frequency as the driving force,

steady =  {x1-> (u1 Exp[I omega #]&), 
           x2-> (u2 Exp[I omega #]&)};

where u1 and u2 are complex amplitudes.

Substituting the force and the steady-state solutions into the equations of motion yields equations for u1 and u2. As the amplitudes are independent of t, the equations can be 
simplified by chosing t = 0.

{eqn[1], eqn[2]} /.force /. steady /. t->0

These equations can be solved for u1 and u2

ans = First[Solve[%, {u1, u2}]]

The Behavior of the System

The symbolic solution encapsulates all the information about the steady state dynamics 
of the system.  However, it is difficult to see immediately the consequences of these equations.

Normalized Displacement

For use in the rest of this analysis, it is convenient to define a normalized displacement,

nu1[omega_,d_,m1_,m2_,k2_] = u1/.ans/.{p0->1,k1->1};
nu2[omega_,d_,m1_,m2_,k2_] = u2/.ans/.{p0->1,k1->1};

No Damping Force: Resonance

What is the behavior of the system when the damping term is zero?  Plot the amplitude 
of the first displacement as a function of frequency.  The remaining parameters are 
chosen to be unity.

Plot[Abs[nu1[omega,0,1,1,1]],{omega,0,2},
	AxesLabel->{omega,Abs[u1]}, PlotRange-> {0, 10}]

There are two resonances in this system. These occur when the denominator of u1 is zero.

Denominator[nu1[omega,0,k2,m1,m2]] == 0

This polynomial equation can be solved for the exact roots.  For brevity, only 
the first root is shown.

Solve[%, omega]//First

Or it can be numerically approximated for specific values of the parameters,

N[% /. {k2->1, m1->1, m2->1}]

The Behavior as the Mass Changes

It is instructive to observe what happens as the mass is varied.  One method of viewing this is animation.

Needs["Graphics`Animation`"]

MoviePlot[Abs[nu1[omega,0,m1,1,1]],{omega,0,2},{m1,1,5,.5},
	PlotRange->{0,10}]

Conditions for Isolation of the First Mass

Notice that at omega=1, u1 is zero, for all values of  m1. That is, the mass does not 
respond to the driving force and has been isolated.  This occurs when the numerator 
of the expression is zero.

Solve[Numerator[nu1[omega,0,m1, m2, k2]]==0, omega]

The Behavior as a Damping Force Is Applied

A final point of interest comes in observing the effect of varying the applied damping.  
Again an animation can be used to show the effect.  Note that the isolation of the first 
mass no longer occurs once a damping term is introduced.

MoviePlot[Abs[nu1[x,d,1,1,1]],{x,0,2},{d,0,.4,.04},
	PlotRange->{0,10}]

An alternative is to use a three-dimensional plot to show the magnitude of the 
displacement as a function of the frequency and the damping term.

Plot3D[Abs[nu1[x,d,1,1,1]],{x,0,2},{d,0,.4},
	PlotPoints->30,PlotRange->{0,10}]