PROBABILITY AND STATISTICS IN ACTUARIAL SCIENCE

Devendra Kapadia

Wolfram Research, Inc.

Outline of the Presentation

In this talk, I would like to :

Give an introduction to the basic ideas and problems of Actuarial Science

Illustrate some of the new functions for Probability and Statistics in Mathematica 8

Solve problems related to a few theoretical models in Actuarial Science

Take a trip through the documentation and give some useful references for Actuarial Science

Introduction to Actuarial Science

What is Actuarial Science?

Actuarial science is the discipline that applies mathematical and statistical methods to assess risk in the insurance and finance industries.

The risks may relate to health, automobiles, financial investments or even life itself.

A key idea at the heart of Actuarial Science is that of redistribution of risk.

For example, people buy insurance because they can redistribute the risk, making it small for each if the number of participants is large.

"When dealt with in sufficient numbers, matters of chance become matters of certainty. “

-George Bernard Shaw

Basic problems of Insurance

In this talk, we will use Probability and  Statistics to study three fundamental problems from the field of insurance:

Loss and claims payment models for general insurance

Proportional and excess of loss models of reinsurance

Calculation of premiums for life insurance

Probability and Statistics

Statistical Distributions

Statistical distributions may be classified as being discrete or continuous.

For example, the Poisson distribution is a discrete distribution :

DiscretePlot[Evaluate[Table[PDF[PoissonDistribution[λ],k],{λ,{5,10,20}}]],{k,0,30},PlotRange->All,PlotMarkers->Automatic]

The normal distribution is an important example of a continuous distribution :

Plot[Evaluate[Table[PDF[NormalDistribution[0,σ],x],{σ,{.75,1,2}}]],{x,-6,6},Filling->Axis]

The exponential distribution is also very useful - it has the memoryless property :

Plot[Evaluate[Table[PDF[ExponentialDistribution[λ],x],{λ,{(1/2),1,2}}]],{x,0,3},Filling->Axis,PlotRange->All]

UniformDistribution and GompertzMakehamDistribution are examples of life distributions :

Plot[Evaluate[Table[PDF[UniformDistribution[{0,max}],x],{max,{1,2,4}}]],{x,0,5},PlotRange->All,Filling->Axis]

Plot[Evaluate[Table[PDF[GompertzMakehamDistribution[λ,1],x],{λ,{0.5,1,3}}]],{x,0,2},PlotRange->All,Filling->Axis]

Probability and Expectation

Many properties of statistical distributions can be expressed in terms of Probability and Expectation.

For example, the CDF (cumulative distribution function) can be defined as a probability :

CDF[NormalDistribution[0,1],x]

cdf=Probability[y≤x,y\[Distributed]NormalDistribution[0,1]]

Plot[cdf,{x,-3,5},PlotStyle->{"Thickness"->0.01,Red},Background->LightGray]

Similarly, the Mean and Variance can be defined as expectations:

𝒟=ExponentialDistribution[λ];

{Mean[𝒟],Variance[𝒟]}

{Expectation[x,x\[Distributed]𝒟],Expectation[(((x-Mean[𝒟]))^2),x\[Distributed]𝒟]}

ProbabilityDistribution

A custom distribution with a known PDF can be defined using ProbabilityDistribution. For example :

Custom𝒟=ProbabilityDistribution[((Sqrt[2])/(π (1+(x^4)))),{x,-∞,∞}];

PDF[Custom𝒟,x]

Plot[Evaluate[PDF[Custom𝒟,x]],{x,-5,5},Filling->Axis]

Custom𝒟/.{ProbabilityDistribution->Integrate}

{Mean[Custom𝒟],Variance[Custom𝒟]}

A custom distribution can also be defined using the CDF :

cdf=Piecewise[{{1-(E^(-(m x))),x≥0}},0]

CDF𝒟=ProbabilityDistribution[{"CDF",cdf},{x,-∞,∞},Assumptions->m>0];

{Mean[CDF𝒟],Variance[CDF𝒟]}

TransformedDistribution

TransformedDistribution represents the distribution obtained by applying a transformation to a random variable with a known distribution.

TransformedDistribution simplifies automatically, wherever this is possible . For example,

TransformedDistribution[x+7,x\[Distributed]UniformDistribution[{1,5}]]

Plot[{PDF[UniformDistribution[{1,5}],x],PDF[UniformDistribution[{8,12}],x]},{x,0,15},Exclusions->None,Filling->Axis]

The following example illustrates the principle of redistribution of risk :

𝒟=NormalDistribution[0,1];

Average𝒟=TransformedDistribution[(1/3) (x1+x2+x3),{x1\[Distributed]𝒟,x2\[Distributed]𝒟,x3\[Distributed]𝒟}]

{Variance[𝒟],Variance[Average𝒟]}

One can sometimes obtain a new parametric distribution using a transformation :

TransformedDistribution[Exp[x],x\[Distributed]NormalDistribution[]]

Let us now consider a distribution obtained by a piecewise transformation, taking values between 0 and 280 :

f[x_]:=Piecewise[{{0,x<20},{x-20,20≤x<300},{280,x≥300}}]

Plot[f[x],{x,0,350},PlotStyle->{Thickness[0.015],Red},Background->LightGray,PlotRange->{0,300}]

Piecewise𝒟=TransformedDistribution[f[x],x\[Distributed]ExponentialDistribution[(1/100)]];

The CDF  of the this distribution has discontinuities at 0 and 280 :

cdf=CDF[Piecewise𝒟,x]

Plot[cdf,{x,-40,350},PlotStyle->{Thickness[0.01],Red},Epilog->{{Blue,PointSize[0.03],Point[{0,((-1+(E^(1/5)))/(E^(1/5)))}]},{Blue,PointSize[0.03],Point[{280,1}]}}]

The PDF of this mixed distribution can be represented using DiracDelta :

PDF[Piecewise𝒟,x]

One can use RandomVariate to study the mixed nature of the distribution in detail :

SeedRandom[0];RandomVariate[Piecewise𝒟,30]

Length[Select[RandomVariate[Piecewise𝒟,(10^5)],#1==280&]]

%/10^5.

NProbability[x==280,x\[Distributed]Piecewise𝒟]

Loss and Claims Payment Models

Loss Models

Suppose that a loss event has a probability of q and that the the loss x, given that an event has occurred, can be modeled by the exponential distribution with parameter a. Then the CDF has the following expression:

LossCDF=((1-q)+q (1-(E^(-a x)))) HeavisideTheta[x];

The plot of the CDF shows the discontinuity at x = 0:

Plot[LossCDF/.{q->(2/3),a->1},{x,-2,7},PlotStyle->{Thickness[0.01],Red},Epilog->{Blue,PointSize[0.03],Point[{0,(1/3)}]},Exclusions->{0}]

Thus, the loss distribution is given by:

Loss𝒟=ProbabilityDistribution[{"CDF",LossCDF},{x,-∞,∞},Assumptions->a>0&&0<q<1];

The  mean and the variance can now be calculated easily:

Mean[Loss𝒟]

Variance[Loss𝒟]

Claims Payment Models

Assume that an insurance scheme has a deductible d and a benefit limit s. Then the claims payment function is given by :

PayoutFunction[x_]:=Piecewise[{{0,x≤d},{x-d,d<x<s+d},{s,x≥s+d}}]

Here is a plot of the payout function for d = 400 and s = 1000 :

Plot[PayoutFunction[x]/.{d->400,s->1000},{x,0,1800},PlotStyle->{Thickness[0.01],Red},Filling->Axis,Exclusions->None]

The distribution of the claims payment is given by:

Payout𝒟=TransformedDistribution[PayoutFunction[x],x\[Distributed]Loss𝒟,Assumptions->d>0&&s>0&&0<q<1&&a>0];

The mean and variance of the claims payment is given by:

m=Mean[Payout𝒟]

v=Variance[Payout𝒟]

The case when there is no benefit limit can be handled by computing the following limits :

Limit[m,s->∞,Assumptions->s>0&&d>0&&a>0]

Limit[v,s->∞,Assumptions->s>0&&d>0&&a>0]

Reinsurance

Proportional Reinsurance

Under a proportional reinsurance agreement, the insurer pays a fixed proportion, say a, of each claim that occurs during the period of the reinsurance arragement.

The remaining fraction, 1-a, of each claim is paid by the reinsurer (for a certain premium paid by the insurer).

Suppose the claims follow a lognormal distribution with parameters μ and σ.

The distribution of the claim paid by the insurer  is given by :

TransformedDistribution[a x,x\[Distributed]LogNormalDistribution[μ,σ]]

The distribution of the claim paid by the reinsurer  is given by :

TransformedDistribution[(1-a) x,x\[Distributed]LogNormalDistribution[μ,σ]]

Excess of Loss Reinsurance

Under an excess of loss reinsurance agreement, a claim is shared between the insurer and reinsurer only if the claim exceeds a fixed amount called the retention level. Otherwise, the insurer pays the claim in full.

Suppose the claims follow a lognormal distribution with parameters μ and σ.

Also, assume that the retention level is M.

The distribution for the claims payments made by the insurer is:

InsurerPayout𝒟=TransformedDistribution[Min[x,M],x\[Distributed]LogNormalDistribution[μ,σ],Assumptions->M>0];

Hence, the expected value of  the claim paid by the insurer is given by:

Mean[InsurerPayout𝒟]

The distribution for the claims payments made by the reinsurer is:

ReinsurerPayout𝒟=TransformedDistribution[Max[0,x-M],x\[Distributed]LogNormalDistribution[μ,σ],Assumptions->M>0];

Hence, the expected value of  the claim paid by the reinsurer is given by:

Mean[ReinsurerPayout𝒟]

Premiums for Life Insurance

Net Single Premium

The expected time value of a death benefit of $1 paid at time t, where t is drawn from a Gompertz–Makeham distribution:

NetSinglePremium=Expectation[TimeValue[Cashflow[{{t,1}}],EffectiveInterest[r,0],0],t\[Distributed]GompertzMakehamDistribution[a,b]]

Net Annual Premium

The annual premium, which is usually paid at the beginning of a policy year, that is necessary to make the expected time value of that payment stream for t periods equal to the net single premium, can be computed as follows:

NetAnnualPremium=FullSimplify[Solve[Expectation[TimeValue[AnnuityDue[premium,t],EffectiveInterest[r,0],0],t\[Distributed]GompertzMakehamDistribution[a,b]]==NetSinglePremium,premium]]

Documentation and Resources

Actuarial Science in Mathematica 8

Actuaries are professionals who deals with the financial impact of risk and uncertainty.

In order to become an actuary, one must pass a rigorous series of exams on topics including Probability.

Several problems based on the exams conducted by the Society of Actuaries are available on the documentation pages for Probability and other functions.

The documentation for Mathematica 8 includes guide pages showing the functions which are relevant to different areas such as Actuarial Science, Finance and Reliability Analysis.

Some useful references

1. Actuarial Models : The Mathematics of Insurance by Vladimir Rotar, Chapman and Hall, 2006.

2. Insurance : Risk and Ruin by David Dickson, Cambridge University Press, 2005.

3. The Vice of Gambling and the Virtue of Insurance by G. B. Shaw in “The World of Mathematics”, 
    Vol. 3.

4. The Sky Is Not Falling, It’s Just Shifting by Jack Heidel, Notices of the AMS, September 2010.

Conclusion and Outlook

Mathematica 8 provides a wide range of statistical functions for studying theoretical models in  Actuarial Science.

The new functionality for non-parametric distributions, estimation, finance, etc. should also be useful for analyzing practical data in a deep way.