"Modeling ATLAS vertex and time Distributions with Satellite Bunches"
							by Sebastian White
								September 10, 2010

To analyze the problem we study the population within an individual beam crossing  in both the spatial domain (z-vertex) and the time domain (t-absolute). We first remind ourselves that, in the traversal of two gaussian beam distributions, the spatial distribution of the Luminosity function, L(z), is an invariant with respect to time. Therefore the measurements by the central detector, of the interaction distribution within a crossing are uncorrelated in space and time.

ie     			L(z,t)=I(z,t)*I(z,-t)=((e^(-((((-c t+z))^2)/(2 (Subscript[σ, l]^2)))-((((c t+z))^2)/(2 (Subscript[σ, l]^2)))))/(2 π (Subscript[σ, l]^2)))=((e^(-(((c^2) (t^2)+(z^2))/(Subscript[σ, l]^2))))/(2 π (Subscript[σ, l]^2)))=L(z)*L(t)

which manifestly factors into the product of 2 Gaussian distributions- one in space with a variance of ((Subscript[σ, l])/(Sqrt[2])) and one in time with a variance of ((Subscript[σ, l])/(c (Sqrt[2]))).

Source Code:

The source code for this mathematica notebook is attached to the ATLAS plot blessing agenda for Sept. 10.  It can be run using the free Mathematica Player package available at http://www.wolfram.com/products/player/download.cgi. You can repeat the calculations for different events, play the animations, etc. If you have access to a Mathematica 7.0.1 license (most Universities and High Energy Physics Laboratories do) then you  can also modify the calculations, choose different assumptions about detector resolutions, etc.

References:

1) LHC Design Report, Volume 1, Chapter 2; https://edms.cern.ch/file/445830/5/Vol_1_Chapter_2.pdf

Basic Fomulae for determining the Luminosity function L (z, t) = L (z)*L (t). The beam cross section is given by ((Subscript[σ, x,y])^2)= (Subscript[ϵ, x,y]) β(z)/(6πγ), where ϵ is the transverse emittance of the beam, the betatron amplitude function, β(z), is the one for a drift since there are no focusing elements in the region of interest and γ is the usual relativistic factor. Since the luminosity is ~ (Subscript[I, 1]) (Subscript[I , 2]) /(  (Subscript[σ, x]) (Subscript[σ, y]) ) , it is weighted by 1/β. We use units of centimeters and nanoseconds throughout.

c=30;
It[z_,t_]:=PDF[NormalDistribution[c*t,7.55],z]

betastar=55;

Betatron[z_]:=betastar+z*z/betastar

Plot[Betatron[z],{z,-20,20}]

A movie of the Luminosity Function for one crossing

Animate[Plot[{It[z,t]*It[z,-t]/Betatron[z],0.0008*PDF[NormalDistribution[0,4.82],z]},{z,-30,30},PlotRange->Full],{t,-1,1},SaveDefinitions->True]

Now Calculate the proper RMS of the space distribution including Betatron Amplitude Function and the crossing angle (vertical at Atlas and horizontal in CMS) of 285 μradians

L[z_?NumericQ]:=NIntegrate[It[z,t]*It[z,-t]/Betatron[z],{t,-10,10}]

sigmalum=Sqrt[NIntegrate[z*z*L[z],{z,-20,20}]/NIntegrate[L[z],{z,-20,20}]]

sigmay=Sqrt[1]*16.7*0.0001;
theta=285*0.000001;
Clear[Lp];
Lp[z_?NumericQ]:=L[z]*NIntegrate[PDF[NormalDistribution[y-theta*z/2,sigmay],y] *PDF[NormalDistribution[y+theta*z/2,sigmay],y],{y,-0.5,0.5}];
Plot[Lp[z],{z,-20,20},PlotRange->Full,Frame->True,FrameLabel->{"Z in Centimeters","Luminosity","Final Luminosity profile in space",""}]

Fig. 1 Luminosity profile along z integrated over time and including machine optics as well as crossing angle

sigmalumi=Sqrt[NIntegrate[z*z*Lp[z],{z,-20,20}]/NIntegrate[Lp[z],{z,-20,20}]];

sigmalum=sigmalumi

Now model LHC with satellite bunches at +/- 5 nsec

Its[z_,t_]:=It[z,t]+0.5*It[z,t+5]+0.5*It[z,t-5];

Animate[Plot[17000*Its[z,t]*Its[z,-t]/Betatron[z],{z,-100,100},PlotRange->{{-100,100},{0,1}},Frame->True,GridLines->{{-75,75},None},PlotStyle->Thick,FrameLabel->{Style["z, interaction Vertex (cms)",18],Style["Event Rate",18],Style["Spacetime distribution of ATLAS events",18]},LabelStyle->Directive[Black,Bold,FontSize->18],ImageSize->560],{{t,-6,"ATLAS proper time(nsec)"},-6,6,0.1},SaveDefinitions->True]

Animate[Plot[{10*It[z,t]},{z,-100,100},PlotRange->{0,.6},
Filling->Axis,
FillingStyle->
ColorData["Rainbow"] [(It[0,t]*It[0,-5]+It[0,t]*It[0,0]+It[0,t]*It[0,+5])/Betatron[0]/maxval],ImageSize->560  ],
{t,-6,6},SaveDefinitions->True]

Three peaks, 5 time units apart, each with its own coloring.

Animate[Plot[{10*It[z,t],It[z,t-5],It[z,t+5]},
{z,-350,350},PlotRange->{0,.6},
Filling->
{
1->{Axis,ColorData["Rainbow"] [(It[0,t]*It[0,0])/Betatron[0]/maxval]},
2->{Axis,ColorData["Rainbow"] [(It[0,t-5]*It[0,0])/Betatron[0]/maxval]},
3->{Axis,ColorData["Rainbow"] [(It[0,t+5]*It[0,0]/maxval)/Betatron[0]]}} ,ImageSize->560],
{t,-10,10},SaveDefinitions->True]

Animate[GraphicsGrid[{{
Plot[It[z,t-5],
{z,-350,350},PlotRange->{0,.6},
Filling->
{1->{Axis,ColorData["Rainbow"] [(It[0,t-5]*It[0,0])/Betatron[0]/maxval]}}  ],
Plot[10*It[z,t],
{z,-350,350},PlotRange->{0,.6},
Filling->
{1->{Axis,ColorData["Rainbow"] [(It[0,t]*It[0,0])/Betatron[0]/maxval]}}  ],
Plot[It[z,t+5],
{z,-350,350},PlotRange->{0,.6},
Filling->
{1->{Axis,ColorData["Rainbow"] [(It[0,t+5]*It[0,0]/maxval)/Betatron[0]]}}  ]  }},
ImageSize->560],
{t,-10,10},SaveDefinitions->True]

The End