The Painlevé Equations and Mathematica

Devendra Kapadia

Wolfram Research, Inc.

({{"      The Painlevé equations are a set of fifty differential equations which arose in Paul Painlevé's (1902) classification of second-order nonlinear ordinary differential equations based on their singularities. Painlevé noted that six out of the fifty equations required new transcendental functions for expressing their general solution.These six Painlevé transcendents have been studied intensively during the last few decades, largely due to their connection with the theory of solitons and integrable systems ", }})

Our purpose here is to give a brief introduction to the the Painlevé equations using DSolve and other functions in Mathematica.

We will begin by considering a linear first-order ordinary differential equation :

DSolve[(x-3)*y'[x] + y[x]==0, y[x], x]

The solution y[x] has a pole at x = 3 but this singularity does not depend on the arbitrary constant C[1] i.e. it is a fixed singularity.

Next, we consider a nonlinear first-order equation :

DSolve[y'[x] +y[x]^2 ==0, y[x], x]

The solution now has a pole at x = C[1], and hence the singularity moves as we vary the arbitrary constant C[1]:

GraphicsRow[Table[Plot[1/(x-c), {x,0, 5}, PlotStyle -> {Thickness[0.01], Red}, PlotRange -> {-10,10}, Ticks -> {Automatic, None}], {c,1,3}], ImageSize -> 700]

It is a general feature of linear differential equations that their singularities are fixed and depend only on the coefficients of the equation. The singularities of nonlinear equations may either be fixed  or movable.

Around 1880, Emile Picard  asked for the determination of ODEs whose solutions have no movable critical points. We will now explain this imporant concept.

A critical point of a differential equation is one where the solution can become multiple-valued.

For example, the following nonlinear first - order ODE has a solution with an algebraic branch point :

DSolve[y'[x] +y[x]^3==0, y[x], x][[1]]

This is an example of a movable critical point since the branch-structure of the solution depends on the initial value prescribed by us.

In modern terminology, an  ODE whose solutions have no movable critical points is said to have the Painlevé property or to be of Painlevé type. Thus, an ODE  of Painlevé type may have solutions with movable poles, movable single-valued essential singularities or fixed singularities.

In 1884, L. Fuchs showed that the Riccati equation

y'(x)==a(x) + b(x) y(x) + c(x) ((y(x))^2)

is essentially the only first-order ODE  all of whose solutions have fixed critical points. This is a remarkable result since the solutions of  Riccati equations can be
given in terms of the solutions of linear second-order  ODEs. For instance, consider the following Riccati equation:

DSolve[u'[x]==(((2 x) u[x])/(1-(x^2)))-(3/(4 (1-(x^2))))-((u[x])^2),u[x],x]

If we set  y(x)=((u'(x))/(u(x))), then the  function y(x) satisfies Legendre's equation :

DSolve[(1-x^2)*y''[x] -2x*y'[x] +(3/4)*y[x]==0, y[x],x]

Thus, the study of nonlinear first-order ODEs having the Painlevé property does not take us beyond the realm of the classical special functions such as Legendre, Bessel and Airy functions, which satisfy linear second-order equations.

({{        "In 1888, Sonya Kovalevskaya used the Painlevé property to find an integrable case of the system of differential equations for a top. She was awarded the Prix Bordin of the French Academy of Science for her solution of these equations using hyperelliptic integrals. In fact the prize money was substantially increased in order to acknowledge the exceptional quality of her work. ", }})

Around the beginning of the twentieth century, Paul Painlevé began a systematic classification of nonlinear second-order ODEs

y''(x)=R(x,y(x),y'(x))

whose solutions are free from movable critical points and where R is a rational function of its arguments. His main tool was the  α-method which relies 
on introducing a parameter called 'α' into the equation. The parameter is chosen so that the ODE can be solved explicitly when α = 0. By studying the 
critical points of this explicit solution, Painlevé was able to derive conclusions about the singularities of the solutions for general values of  'α'.  
Painlevé and  his student B. Gambier (1910), showed that any nonlinear second-order ODE of the desired type can be reduced to one of  fifty basic
equations using bilinear transformations. These fifty equations are called the Painlevé  equations.

The fifty Painlevé  equations can be divided into two groups:

1. The first group consists of forty-four of these equations can either be explicitly solved in terms of known elementary or special functions or 
   can be reduced to first-order nonlinear ODEs  after a single integration. We give below two of these equations and their solution using DSolve. 
   The numbering used by us is that given on pages 12-13 in the paper by Gambier (1910).

Painlevé  Equation 3 (solution is given in terms of Weierstrassian elliptic functions)

DSolve[y''[x] == 6*y[x]^2 - 1/24, y[x], x]

Painlevé  Equation 17 (solution is given in terms of polynomials for positive integers m):

DSolve[w''[z] ==((m-1)/(m*w[z]))*w'[z]^2, w, z]

m=5;

DSolve[w''[z] ==((m-1)/(m*w[z]))*w'[z]^2, w, z]

Clear[m]

2. The remaining six Painlevé  equations have been shown to require new transcendental functions in order to express their general solutions. We list 
    below these six Painlevé  transcendents :

y''==6 (y^2)+x

y''==2 (y^3)+x y+α

y''==γ (y^3)+(((y')^2)/y)+((α (y^2)+β)/x)+(δ/y)-((y')/x)

y''==((3 (y^3))/2)+4 x (y^2)+2 ((x^2)-α) y+(1/2) y ((y')^2)+(β/y)

y''==((1/(2 y))+(1/(y-1))) ((y')^2)+(((((y-1))^2) ((β/y)+α y))/(x^2))+((γ y)/x)-((y')/x)+(((y(y+1)) δ)/(y-1))

y''==(1/2) ((1/(y-x))+(1/y)+(1/(y-1))) ((y')^2)-((1/(y-x))+(1/x)+(1/(x-1))) y'+(((y (y-1) (y-x)))/((x^2) (((x-1))^2)))(α+((γ (x-1))/(((y-1))^2))+((δ x (x-1))/(((y-x))^2))+((x β)/(y^2)))

The above equations are traditionally called Painlevé  I, Painlevé  II, etc. and hence we shall refer to them using this scheme.

Painlevé  I can be solved using a series solution having a pole of order 2 at the origin. We give below the first few terms of this solution and verify that the equation is approximately satisfied for values of 'x'  close to the origin, with 'b' being an arbitrary parameter.

y[x_]=(1/(x^2))-((x^3)/6)+b (x^4)

Table[y''[x]-6*y[x]^2-x/.{ b-> Random[Real, {-5,5}, 20], x->Random[Real, {0,1/100}, 20]}, {i,300}]//Max

Clear[y]

It should be noted that the WeierstrassP function which satisfies an equation similar to Painlevé I  also has a pole of order 2 in its series expansion around the origin. For example,

Series[WeierstrassP[x, {3,-7}], {x,0, 5}]

The remaining five Painlevé equations have special solutions in terms of rational functions, special functions etc. and they also possess properties which are characteristic of integrable systems such as Bäcklund transformations. We will now illustrate some of these features using Painlevé  II and  Painlevé  IV.

We will begin by considering Bäcklund transformations which map solutions of a given differential equation with parameters to solutions of the same equation but with different values of the parameters.

Now,  Painlevé II is the following nonlinear second-order ODE with a parameter α:

PainleveII=y''[x]==2 ((y[x])^3)+x y[x]+α;

Clearly, y[x] == 0 is a solution of this equation if α == 0. We use this solution as a seed for a family y1[x, α] of solutions for Painlevé II by setting:

y1[x_, 0]:=0

To proceed further, we consider the following  Bäcklund transformation for Painlevé II :

y1[x_,α_]:=-y1[x,α-1]-((2 α-1)/(2 ((y1[x,α-1])^2)+2 (∂_x)y1[x,α-1]+x))

The first few members of the family are given by:

TableForm[Apart[Table[{α, y1[x, α]}, {α, 1, 4}]]]

({{1,                              -(1/x)}, {2,                           (1/x)-((3 (x^2))/(4+(x^3)))}, {3,                      ((3 (x^2))/(4+(x^3)))-((6 (10 (x^2)+(x^5)))/(-80+20 (x^3)+(x^6)))}, {4,        -(1/x)+((6 (10 (x^2)+(x^5)))/(-80+20 (x^3)+(x^6)))-((9 (40 (x^5)+(x^8)))/(11200+60 (x^6)+(x^9)))}})

It is easy to verify that the functions  y1[x, α] satisfy Painlevé II :

Table[D[ y1[x, α], {x, 2}] == 2*y1[x, α]^3 +x*y1[x, α] +α,  {α, 0, 7}]//Simplify

Clear[y1]

Thus, we have used Bäcklund transformations to construct rational solutions of Painlevé II for all non-negative integer values of α.

Another interesting approach for constructing rational solutions of Painlevé II is to consider the family of Vorob'ev - Yablonskii polynomials Q[n, z], given by

Clear[Q]

Q[0,x_]:=1

Q[1,x_]:=x

Q[n_, x_]:= Q[n, x]=Together[(x*Q[n-1,x]^2-4*Q[n-1, x]*D[Q[n-1, x], {x,2}]+4*D[Q[n-1,x], x]^2)/Q[n-2, x]]

The first few  Vorob'ev - Yablonskii polynomials are given explicitly by :

TableForm[Table[{n, Expand[Together[Q[n, x]]]}, {n, 0, 5}]]

({{0,                                    1}, {1,                                    x}, {2,                                4+(x^3)}, {3,                        -80+20 (x^3)+(x^6)}, {4,                      11200 x+60 (x^7)+(x^10)}, {5,    -6272000-3136000 (x^3)+78400 (x^6)+2800 (x^9)+140 (x^12)+(x^15)}})

As seen in the example below, the roots of the Vorob'ev - Yablonskii polynomials lie on curved, approximate equilateral triangles.

sol =NRoots[Together[Q[14, x]]==0, x];ListPlot[{Re[x], Im[x]}/.{ToRules[sol]}, PlotStyle -> {PointSize[0.03], Red}, Background -> Cyan, AspectRatio -> 1]

The rational solutions of Painlevé II can be constructed using the Vorob' ev - Yablonskii polynomials as follows :

y2[x_, 0]:=0

y2[x_, α_]:= D[Log[Q[α-1, x]/Q[α, x]], x]

Since there is a unique rational solution of Painlevé II for each non - negative integer α, the family y2[x, α] is identical with the family y1[x, α] obtained from Bäcklund transformations.

Table[{α, y2[x,α]}, {α, 1, 4}]//Apart//TableForm

({{1,                      -(1/x)}, {2,                   (1/x)-((3 (x^2))/(4+(x^3)))}, {3,                ((3 (x^2))/(4+(x^3)))-((6 (10 (x^2)+(x^5)))/(-80+20 (x^3)+(x^6)))}, {4,         -(1/x)+((6 (10 (x^2)+(x^5)))/(-80+20 (x^3)+(x^6)))-((9 (40 (x^5)+(x^8)))/(11200+60 (x^6)+(x^9)))}})

The general solutions of  Painlevé II - V for arbitrary values of the parameters in them cannot be expressed in terms of the classical special functions such as Airy, Bessel, etc. However, they do have special function solutions for specific values of the parameters .  The basic idea is to rewrite each Painlevé equation in terms of a Riccati equation, which can be solved by reducing it to a linear second-order equation.  The solutions of these Riccati equations typically involve special functions, thereby giving the required solutions for the Painlevé equations. We will give an example of this type using Painlevé IV.

We begin with the following Riccati equation with parameter α. This equation can be solved in terms of Hermite and Hypergeometric functions using DSolve.

sol=DSolve[y'[x] ==y[x]^2+2x*y[x] -2(1+α), y, x]

As seen below, the solution of the Riccati equation satisfies PainleveIV whenever the parameters α and β in it are related by  β == -2*(1 + α)^2.

PainleveIV=y''[x]==((3 ((y[x])^3))/2)+4 x ((y[x])^2)+2 ((x^2)-α) y[x]+(((y'[x])^2)/(2 y[x]))+(β/(y[x]));

Table[(PainleveIV[[1]] - PainleveIV[[2]] )/. {β -> -2*(1 + α)^2} /. sol[[1]]/.{α->7, x-> 2}, {m,0,5, 1/2}]//FullSimplify//Union

There are many other fascinating aspects of the Painlevé equations for which we refer you to the books and articles listed below. The theory of the  Painlevé  transcendents is a rapidly evolving field and, once a complete framework is available for algorithmic implementation of these new special functions, we hope to assimilate these beautiful and profound developments into DSolve and other areas of Mathematica.

References :

1. Painlevé, P., "Sur les équations différentielles du second ordre et d'ordre supérieur dont l'intégrale générale est uniforme." Acta Math.21, 1 - 85, 1902.

2. Gambier, B., "Sur les équations différentielles du second ordre et du premier degré dont l'intégrale générale est à points critique fixés." Acta.Math.33, 
    1 - 55, 1910.

3. Ince, E. L., "Ordinary Differential Equations", New York, Dover, pp.345 - 347, 1956.

4. Clarkson, P. A., "Painlevé equations - nonlinear special functions", in Orthogonal Polynomials and Special Functions : Computation and Application
   (Editors F Márcellan and W van Assche), Lecture Notes in Mathematics, vol.1883, Springer-Verlag, Berlin (2006) pp 331 - 411.

5. Wolfram, S., "The History and Future of Special Functions",  Talk given at the Wolfram Technology Conference, 2005

6. Conte, R., "The Painlevé Property - One Century Later", CRM Series in Mathematical Physics, Springer - Verlag, 1999.